Weihnachtsstern mit LEDs – Teil 2 am Arduino

In dem zweiten Teil 2 zum 3D gedruckten Weihnachtsstern soll es nun darum gehen, wie du diesen am Arduino programmieren kannst.

Im letzten Beitrag Weihnachtsstern mit RGB LEDs WS2812B – Teil 1 Aufbau habe ich dir gezeigt wie dieser aufgebaut wird. Auch habe ich dir dort bereits ein kleines Programm gezeigt, wie du die RGB LEDs im Kreis als Lauflicht laufen lassen kannst.

Hier möchte ich dir jetzt zeigen, wie die RGB LEDs mit einer Infrarot-Fernbedienung steuerst.

Benötigte Ressourcen für dieses Projekt

Wenn du dieses Projekt nachbauen möchtest, dann benötigst du:

• einen Arduino UNO R3,
• ein Datenkabel,
• ein Infrarot Empfänger,
• eine Infrarot-Fernbedienung,
• ein paar Breadboardkabel,
• ein 400 Pin Breadboard

Auf ebay.de gibt es einige Sets mit dem Arduino UNO wo ein Datenkabel beiliegt, jedoch ist dieses meistens nur sehr kurz und daher empfehle ich dir eines mit min. 1,5 m Länge zu besorgen.

Die Infrarot-Fernbedienung musst du dir nicht unbedingt kaufen, solltest du zu Hause noch Geräte mit Fernbedienung haben, zbsp. Fernseher, Receiver, DVD-Player etc. dann kannst du auch diese verwenden.

Infrarot-Fernbedienung auslesen

Damit wir die RGB LEDs per Infrarot Fernbedienung steuern können, müssen wir zunächst die Fernbedienung auslesen. Wie man dieses macht, habe ich dir bereits im Beitrag Arduino Lektion 20: IR Fernbedienung auslesen ausführlich gezeigt.

In diesem Beispiel verwende ich die kleine, einfache IR Fernbedienung für den Arduino, welche es auf ebay.de recht günstig bereits ab 3 € gibt. Wie erwähnt kannst du auch jede andere nutzen, zbsp. eine von einem RGB LED Spot.

Der Vorteil der Fernbedienung von einem RGB LED Spot liegt auf der Hand, denn diese ist bereits mit Tasten für Farben und Effekte belegt, welche wir dann nur programmieren müssen.

Einfache Schaltung zum auslesen einer IR-Fernbedienung

Wie du eine IR Fernbedienung am Arduino auslesen kannst, habe ich dir bereits im Beitrag Arduino Lektion 20: IR Fernbedienung auslesen ausführlich gezeigt.

Jede Fernbedienung hat eigene Codes, daher musst du vor dem nächsten Schritt zunächst deine Fernbedienung auslesen.

//Bibliothek zum Empfangen und auswerten
//von IR Daten
#include <IRremote.h>

//onoard LED auf dem Arduino am digitalen Pin D13
#define statusLed 13
//IR Receiver Diode mit dem digitalen Pin D10 verbunden
#define irReceiverDiode 10

void setup() {
  //definieren, das der Pin der LED als Ausgang dient
  pinMode(statusLed, OUTPUT);

  //definieren, dass der Pin der IR Diode als Eingang dient
  pinMode(irReceiverDiode, INPUT);

  //beginn der Kommunikation
  IrReceiver.begin(irReceiverDiode, ENABLE_LED_FEEDBACK);
  //beginn der Kommunikation mit 9600 baud
  Serial.begin(9600);
}

void loop() {
  //wenn Daten empfangen wurden, dann...
  if (IrReceiver.decode()) {
    //speichern der Daten in einer Variable
    int value = String(IrReceiver.decodedIRData.command, DEC).toInt();
    //leeren des Puffers
    IrReceiver.resume();
    //ausgeben der Daten auf der seriellen Schnittstelle
    Serial.println(value);
    //aktivieren der Status LED
    digitalWrite(statusLed, HIGH);
    //kleine Pause von 75ms.
    delay(75);
    //deaktivieren der Status LED
    digitalWrite(statusLed, LOW);
  }
}

Wenn wir diesen Code auf den Mikrocontroller überspielen und unsere IR Fernbedienung betätigen, sollten wir auf dem seriellen Monitor die Zahlenwerte für diese Tasten sehen.

Nachdem wir nun die Werte ermittelt haben, können wir die Tasten mit verschiedenen Effekten belegen.

Farbwechsel auf Tastendruck

Im ersten Beitrag hatte ich dir bereits gezeigt, wie du die LEDs in einem Lauflicht im Weihnachtsstern rotieren lassen kannst. Nun möchte ich dir gerne zeigen, wie du per Tastendruck auf der IR Fernbedienung die Farbe ändern kannst.

Die möglichen Farbwerte können wir von der Webseite http://fastled.io/docs/3.1/struct_c_r_g_b.html entnehmen.

Zunächst legen wir uns ein Array mit den möglichen Werten an.

//Farben für unserer LED Lauflicht
CRGB colors[] = {CRGB::Red, CRGB::Yellow, CRGB::Blue, CRGB::Green, CRGB::Violet, CRGB::White};

Hier jetzt das komplette Programm um die LEDs per IR Fernbedienung zu steuern.

//Bibliothek zum empfangen und auswerten
//von IR Daten
#include <IRremote.h>

// Importieren der Bibliothek "FastLED"
#include <FastLED.h>

// Wieviele LEDs sind auf dem LED Stripe?
#define NUM_LEDS 6

// digitaler Pin an welchem der LED Stripe angeschlossen ist
#define DATA_PIN 3

// Ein Array mit den LEDs
CRGB leds[NUM_LEDS];

//IR Receiver Diode mit dem digitalen Pin D10 verbunden
#define irReceiverDiode 10

//Farben für unserer LED Lauflicht
CRGB colors[] = {CRGB::Red, CRGB::Yellow, CRGB::Blue, CRGB::Green, CRGB::Violet, CRGB::White};
//aktuelle Farbe für das Lauflicht
CRGB color = colors[0];

void setup() {
  //definieren das der Pin der IR Diode als Eingang dient
  pinMode(irReceiverDiode, INPUT);

  //beginn der Kommunikation
  IrReceiver.begin(irReceiverDiode, ENABLE_LED_FEEDBACK);
  //beginn der Kommunikation mit 9600 baud
  Serial.begin(9600);

  //definieren des WS2812B LED Stripe vom Typ GRB (Green, Red, Blue)
  //sollte ggf. ein anderer Typ verwendet werden so muss dieser hier angepasst werden.
  //Mögliche Typen sind im Blink Beispiel unter https://github.com/FastLED/FastLED/blob/master/examples/Blink/Blink.ino
  // enthalten.
  FastLED.addLeds<WS2812B, DATA_PIN, GRB>(leds, NUM_LEDS);
}

void loop() {
  // eine Schleife von 0 bis NUM_LEDS
  for (int i = 0; i <= NUM_LEDS; i++) {
    // LED an Position "i" in ROT
    leds[i] = color;
    // aktivieren der gesetzen Werte
    FastLED.show();
    // eine Pause von 50ms.
    delay(50);
    // deaktivieren der LED / es wird lediglich die Farbe schwarz gesetzt
    leds[i] = CRGB::Black;
    // aktivieren der gesetzen Werte
    FastLED.show();
    //wenn Daten empfangen wurden, dann...
    if (IrReceiver.decode()) {
      //speichern der Daten in einer Variable
      int value = String(IrReceiver.decodedIRData.command, DEC).toInt();
      //leeren des Puffers
      IrReceiver.resume();
      //ausgeben der Daten auf der seriellen Schnittstelle
      Serial.println(value);
      
      int index = 0;

      /**
         Taste - Code - Farbe - Farbwert
         1     - 22   - rot   - CRGB::Red
         2     - 25   - gelb  - CRGB::YELLOW
         3     - 13   - blau  - CRGB::Blue
         4     - 12   - gruen - CRGB::Green
         5     - 24   - lila  - CRGB::Violet
         6     - 94   - weiß  - CRGB::White
      */

      switch (value) {
        case 22: index = 0; break;
        case 25: index = 1; break;
        case 13: index = 2; break;
        case 12: index = 3; break;
        case 24: index = 4; break;
        case 94: index = 5; break;
        default: index = 0;
      }
      //überschreiben der aktuellen Farbe mit dem
      //Wert aus dem Array mit den Farben
      color = colors[index];
    }
  }
}

Wenn das Programm auf den Arduino UNO gespielt wurde, dann können wir mit der IR Fernbedienung die Farbe ändern.