Joystick Modul – fünf Richtungen Taster Modul

In diesem Beitrag möchte ich das Modul mit einem fünf Richtungen Taster am Arduino Nano vorstellen.

Bezug

Den hier vorgestellten fünf Richtungen Taster für den Arduino / Raspberry Pi habe ich recht günstig auf aliexpress.com erstanden. Du bekommst diesen aber auch auf ebay.de für bereits 2,92 € zzgl. Versandkosten.

Aufbau des fünf Richtungen Tasters

Das mir vorliegende Modul verfügt auf der Platine über einen Tastknopf, welcher in fünf Richtungen bewegt werden kann. Die Richtungen sind links, rechts, hoch, runter und unten.

Auf der Platine selber sind noch zwei kleine Taster verbaut, welche mit „SET“ & „RST“ beschriftet sind.

Technische Daten des Moduls

Hier die technischen Daten des fünf Richtungen Taster Moduls:

• Betriebsspannung: 2 V bis 9 V
• Umgebungstemperatur: -40 °C bis 85 °C
• Abmaße (L x B x H): 40 mm x 20 mm x 10 mm

Unterschied zum analogen Joystick

Ein Joystick Modul für den analogen Anschluss habe ich dir bereits für den Arduino / Raspberry Pi im Beitrag Arduino Lektion 38: Joystick vorgestellt.

Im Beitrag Arduino Leonardo & Joystick als Mausersatz habe ich dir gezeigt, wie einfach du diesen analogen Joystick als Mausersatz am PC programmieren kannst.

Der analoge Joystick fährt automatisch in die Mittelposition zurück, wenn du diesen loslässt. Dieses Feature ist bei jedem Joystick gleich. Das hier gezeigte fünf Richtungen Modul arbeitet mit einem Taster und dieser führt beim Drücken in die Richtung einen Tastvorgang aus und gibt somit ein Signal ab.

Pinout des fünf Richtungen Tasters

Das Modul verfügt über sieben Pins, welche auf der Vorderseite der Platine beschriftet sind.

Pin Beschriftung	Bezeichnung
COM	„Common end“ für VCC oder GND
UP	Hoch
DWN	Runter
LFT	Links
RHT	Rechts
MID	Unten
SET	Taster SET
RST	Taster RST

Anschluss an den Arduino Nano V3

Das Taster Modul wird wie folgt an den Arduino Nano V3 angeschlossen.

In diesem Beispiel verwende ich keine PullUp Widerstände, dieses löse ich im Quellcode mit einer entsprechenden Konstante beim Initialisieren des digitalen Pins.

Programmieren des Moduls am Arduino Nano V3

Im nachfolgenden kleinen Beispiel habe ich das Modul mit sieben Breadboardkabel an einen Arduino Nano V3 angeschlossen. Zunächst gebe ich nur die Werte wie diese auf der Platine aufgedruckt sind auf dem seriellen Monitor aus.

fünf Richtungen Taster Modul für Arduino & Raspberry Pi in Action

Dieses Video auf YouTube ansehen.

//Bibliothek um einen Taster zu entprellen
#include <Bounce2.h>

// Die Taster sind an den
// digitalen Pins 2 .. 8 angeschlossen
#define up 8
#define dwn 7
#define lft 6
#define rht 5
#define mid 4
#define set 3
#define rst 2

//Konstante für die Pause um den Taster zu entprellen
const int DELAY = 50;

//Definieren der Bounce2 Button Objekte
Bounce btnUp = Bounce(up, DELAY);
Bounce btnDown = Bounce(dwn, DELAY);
Bounce btnLeft = Bounce(lft, DELAY);
Bounce btnRight = Bounce(rht, DELAY);
Bounce btnMiddle = Bounce(mid, DELAY);
Bounce btnSet = Bounce(set, DELAY);
Bounce btnReset = Bounce(rst, DELAY);

void setup() {
  //begin der seriellen Kommunikation mit 9600 baud
  Serial.begin(9600);
  //die Taster sind über einen internen 10 kOhm Widerstand
  //an den digitalen Pin angeschlossen
  pinMode(up, INPUT_PULLUP);
  pinMode(dwn, INPUT_PULLUP);
  pinMode(lft, INPUT_PULLUP);
  pinMode(rht, INPUT_PULLUP);
  pinMode(mid, INPUT_PULLUP);
  pinMode(set, INPUT_PULLUP);
  pinMode(rst, INPUT_PULLUP);
}

/**
   Funktion zum aktualisieren der Taster
*/
void updateButtons() {
  btnUp.update();
  btnDown.update();
  btnLeft.update();
  btnRight.update();
  btnMiddle.update();
  btnSet.update();
  btnReset.update();
}

/**
   Funktion zum prüfen ob ein Taster gedrückt ist.
   @param btn - der Taster welcher geprüft werden soll
   @param btnText - der Text welcher den Taster repraesentiert
*/
void checkButtonPressed(Bounce btn, String btnText) {
  if (btn.fell()) {
    pressBtn(btnText);
  }
}

void loop() {
  //aktualisieren der Taster
  updateButtons();
  //prüfen ob ein Taster gedrückt wurde
  checkButtonPressed(btnUp, "UP");
  checkButtonPressed(btnDown, "Down");
  checkButtonPressed(btnLeft, "Left");
  checkButtonPressed(btnRight, "Right");
  checkButtonPressed(btnMiddle, "Middle");
  checkButtonPressed(btnSet, "Set");
  checkButtonPressed(btnReset, "Reset");
}

/**
   Funktion zum ausgeben einer Textzeile auf
   der seriellen Schnittstelle.
   @param button - der Text welcher einen gedrückten Taster repraesentiert
*/
void pressBtn(String button) {
  Serial.println("Taster " + button + " wurde gedrückt!");
}