Arduino Lektion 44: BME280 Temperatur, Luftfeuchtigkeit und Luftdruck Sensor

In diesem Tutorial möchte ich den Sensor BME280 vorstellen. Mit diesem Sensor kannst du die Umweltdaten wie Temperatur, Luftfeuchtigkeit und Luftdruckmessen. Dieser Sensor wurde mir vom Onlineshop Makershop.de kostenlos für dieses Review zur Verfügung gestellt.

Technische Daten

• Abmaße (L x B) – 14 mm x 10 mm
• Betriebsspannung – 1.8V bis 5V
• Schnittstelle – I2C
• Messbereiche
  • Temperatur -40 °C bis +85 °C
  • Luftdruck 300hPa bis 1100hPa ±0.25 %
  • Luftfeuchtigkeit ±3 % relative Genauigkeit, ≤ 2 % Hysterese

Anschluss

Der Sensor verfügt über 4 Pins, welche wie folgt an den Arduino UNO angeschlossen werden:

BME280	Arduino UNO
VIN	5V
GND	GND
SCL	analoger PIN A5
SDA	analoger PIN A4

Schaltung

In diesem Kapitel möchte ich nun eine kleine Schaltung mit dem Sensor und einem Display für die Ausgabe der Werte erzeugen.

Wenn du diese Schaltung nachbauen möchtest, so benötigst du:

• 1x Arduino Nano
• 1x Sensor BME280
• 4x Breadboard Kabel
• 1x Breadboard 400 Pin

Bibliothek

Für den Sensor gibt es eine Bibliothek von Adarfuit welche über die Arduino IDE installiert werden kann. Wie genau das funktioniert, habe ich im nachfolgenden Video gezeigt.

Zusätzlich wird noch die Bibliothek Adafruit Sensor benötigt. Diese kann leider nur vom GitHub Repository https://github.com/adafruit/Adafruit_Sensor geladen werden.

Bedauerlicherweise hat diese Bibliothek mit meinem Arduino Nano nicht funktioniert, daher habe ich zur Bibliothek von http://cactus.io gewechselt. Hier musste ich im Beispiel nur die I2C Adresse “0x76” auskommentieren. Und es funktionierte von Anhieb sehr gut.

Quellcode

Beispiel zur Bibliothek von http://cactus.io

Den nachfolgenden Quellcode habe ich von der Seite http://cactus.io/hookups/sensors/barometric/bme280/hookup-arduino-to-bme280-barometric-pressure-sensor kopiert und deutsche Texte verpasst. Das Beispiel erzeugt auf dem seriellen Monitor eine Ausgabe.

/***************************************************************************
  This is a library for the BME280 humidity, temperature & pressure sensor
  Designed specifically to work with the BME280 Breakout board
  ----> http://www.adafruit.com/products/2650
  This sketch only supports the I2C bus for connection.
 ***************************************************************************/

#include <Wire.h>
#include "cactus_io_BME280_I2C.h"

BME280_I2C bme(0x76);  // I2C using address 0x76

void setup() {
  Serial.begin(9600);
  Serial.println("BME280 Luftdruck, Luftfeuchtigkeit, Temperatur Sensor | cactus.io"); 
  Serial.println("-----------------------------------------------------------------");
  Serial.println("");

  if (!bme.begin()) {
    Serial.println("Es konnte kein BME280 Sensor gefunden werden!");
    Serial.println("Bitte überprüfen Sie die Verkabelung!");
    while (1);
  }

  bme.setTempCal(-1);
  
  Serial.println("Luftdruck\tLuftfeuchtigkeit\t\tTemperatur(Celsius)\t\tTemperatur(Fahrenheit)");
}

void loop() {
    bme.readSensor(); 
 
    Serial.print(bme.getPressure_MB()); Serial.print("\t\t");    // Pressure in millibars
    Serial.print(bme.getHumidity()); Serial.print("%\t\t\t\t");
    Serial.print(bme.getTemperature_C()); Serial.print(" °C\t\t\t");
    Serial.print(bme.getTemperature_F()); Serial.println(" °F");
    
    delay(2000);
}

Beispiel – Ausgabe auf einem 0,9″ OLED Display

Für diese Schaltung benötigst du:

• einen Taster
• einen 10kOhm Widerstand (als PullDown)
• ein 0,91″ OLED Display
• einen Arduino Nano
• 12 Breadboard Kabel
• ein 400 PIN Breadboard
• ein BME280 Sensor

Quellcode

#include <Wire.h>
#include "cactus_io_BME280_I2C.h"

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define OLED_RESET 4
Adafruit_SSD1306 display(OLED_RESET);

#define NUMFLAKES 10
#define XPOS 0
#define YPOS 1
#define DELTAY 2

#if (SSD1306_LCDHEIGHT != 32)
#error("Height incorrect, please fix Adafruit_SSD1306.h!");
#endif

#define BTN_UP 9

int statusBtnUp = 0; //Status des Tasters
int index = 1; // Zählvariable

BME280_I2C bme(0x76);  // I2C using address 0x76

void setup() {
  Serial.begin(9600);

  //Setup für den BME280 Sensor
  if (!bme.begin()) {
    Serial.println("Es konnte kein BME280 Sensor gefunden werden!");
    Serial.println("Bitte überprüfen Sie die Verkabelung!");
    while (1);
  }
  bme.setTempCal(-1);
  
  //Setup für das Display
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.display();
  delay(1000);
  display.clearDisplay();

  //Setup für den Button
  pinMode(BTN_UP,INPUT);
}
 
void loop() {
    bme.readSensor();

    statusBtnUp = digitalRead(BTN_UP);
    Serial.println(statusBtnUp);
    
    if(statusBtnUp == HIGH && index <3){ 
      index = index+1;
    } else if (statusBtnUp == HIGH && index ==3){
      index = 1;
    }

   switch(index){
     case 1: zeigeTemperatur(); break; 
     case 2: zeigeLuftfeuchtigkeit(); break;
     case 3: zeigeLuftdruck(); break;
   }    
}

void zeigeTemperatur(){
  String tempC = String(bme.getTemperature_C())+"C";
  displayText("Temperatur", tempC);
}

void zeigeLuftfeuchtigkeit(){
  String humidity = String(bme.getHumidity())+"%";
  displayText("Luftfeuchtigkeit", humidity);
}

void zeigeLuftdruck(){
   String pressure = String(bme.getPressure_MB())+" mPa";
   displayText("Luftdruck", pressure);
}

void displayText(String row1, String row2){
  delay(1000);
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0,0);
  display.println(row1);
  display.setCursor(0,10);
  display.println(row2);
  display.display();
  display.clearDisplay();
}

Video