Reichweitenvergleich Ultraschall Abstandssensor HC-SR04 & Laser Distanzsensor VL53LXX-V2

In diesem Beitrag möchte ich dir zeigen welche unterschiede es ggf. in der Reichweite zwischen dem Ultraschallabstandssensor HC-SR04 & Laser Distanzsensor VL53LXX-V2 gibt.

Den Ultraschallabstandssensor HC-SR04 habe ich bereit im Beitrag Arduino Lektion 9: Ultraschall Modul HC-SR04 und den Laser Distanzsensor VL53LXX-V2 im Beitrag Arduino Lektion #103: Laser Distanz Sensor VL53LXX-V2 ausführlich vorgestellt.

Bezug

Beide hier gezeigten Sensoren findest du recht günstig auf den bekannten Internetportalen ebay.de, wish.com, banggood.com und auch auf amazon.de

Sensor	ebay.de	wish.com	banggood.com	amazon.de
HC-SR04	1€ .. 3€	2€ .. 3€	1,29$ .. 2,04$	150.. 2,09€*
VL53LXX-V2	3,2€ .. 6,9€	–	–	21€**

* Umgerechnet aus einer Mehrfachpackung.

** Ein Modul für einen Quadcopter welcher über eine Schnittstelle verfügt.

Ich habe die Module jeweils über ebay.de von einem asiatischen Verkäufer bezogen.

Aufbau der Schaltung

Wie bereits erwähnt habe ich beide Module (HC-SR04 & VL53LXX-V2) bereits jeweils ein eigenes, ausführliches Tutorial gewidmet. Hier nun die Schaltung wie man beide Module auf einem Breadboard an einem Arduino UNO anschließt.

Für den Nachbau der Schaltung benötigst du:

• einen Arduino UNO,
• ein 400 Pin Breadboard,
• ein Ultraschallsensor HC-SR04,
• ein Laser Distanzsensor VL53LXX-V2,
• diverse Breadboardkabel

Die Sensoren werden wie folgt am Arduino UNO angeschlossen:

Sensor	Arduino UNO
Ultraschall Abstandssensor HC-SR04
VCC	5V
TRIG	digitaler Pin D2
ECHO	digitaler Pin D1
GND	GND
Laser Distanzsensor VL53LXX-V2
VIN	5V
GND	GND
SCL	analoger Pin A5
SDA	analoger Pin A4

Programmieren

Der Laser Distanzsensor wird über I2C angeschlossen und der Ultraschall Abstandssensor über digitale Pins, somit ist es recht einfach beide Sensoren an einem Board zu betreiben. 

//Bibliothek für das auslesen des Laser Distanzsensors
#include "Adafruit_VL53L0X.h"

//Konstanten / Variablen für den Laser Distanzsensor
Adafruit_VL53L0X lox = Adafruit_VL53L0X();

//Um die Debug Ausgaben zu aktivieren
//muss dieser Wert auf "true" gesetzt werden.
#define debugSensor false

//Konstanten / Variablen für den Ultraschall Abstandssensor HC-SR04
const int TrigPin = 2;  //Der PIN welcher auf das Trigger Signal gelegt wird.
const int EchoPin = 3;  //Der PIN welcher auf das Echo Signal gelegt wird.
float cm;

void setup() {
  Serial.begin(9600); //Die Übertragungsgeschwindigkeit setzen.
  pinMode(TrigPin, OUTPUT); //Den Trigger auf das Output Signal des Sainsmart setzen.
  pinMode(EchoPin, INPUT);  //Das Echo auf das Input Signal des Sainsmart setzen.

  //Wenn der Serielle Port bereit ist dann eine Ausgabe auf diesen tätigen
  //und prüfen ob der Sensor korrekt angeschlossen ist (ob dieser Ansprechbar ist)
  if (!lox.begin()) {
    Serial.println("Fehler beim lesen des Sensors!");
    while (1); //eine Endlos Schleife
  }
}

void loop() {
  Serial.println("");
  readLaserDistanceValue();
  readUltrasonicValue();
  delay(2500); //1sek. warten

}

void readLaserDistanceValue() {
  //instanziieren des Sensors zum empfangen von Daten
  VL53L0X_RangingMeasurementData_t measure;
  lox.rangingTest(&measure, debugSensor);

  //lesen des Sensor Status
  //der Sensor kann verschiedene Status annehmen,
  //jedoch interessiert für uns nur der Wert "4"
  int sensorStatus = measure.RangeStatus;
  Serial.print("Laser Distanzsensor VL53LXX-V2:\t\t");
  //Wenn Daten empfangen wurden dann...
  if (sensorStatus != VL53L0X_DEVICEERROR_MSRCNOTARGET) {
    Serial.print(measure.RangeMilliMeter / 10);
    Serial.println("cm");
  } else {
    //Wenn keine Daten empfangen wurden dann wird das wahrscheinlich außerhalb der Reichweite sein.
    Serial.println("-out of Range-");
  }
}

void readUltrasonicValue() {
  digitalWrite(TrigPin, LOW); //Trigger Signal ausschalten
  delayMicroseconds(2);   //2 ms warten
  digitalWrite(TrigPin, HIGH);  //Trigger Signal einschalten
  delayMicroseconds(10);  //10ms warten
  digitalWrite(TrigPin, LOW); //Trigger Signal ausschalten
  cm = pulseIn(EchoPin, HIGH) / 58.0; //Das Empfangene Echo Signal in cm umrechnen
  //Da der Sensor mit einer Messgenauigkeit von 0,3cm arbeitet können wir das
  //Ergbnis auf 2 Nachkommastellen begrenzen
  cm = (int(cm * 100.0)) / 100.0;
  Serial.print("Ultraschall Abstandssensor HC-SR04:\t");
  Serial.print(cm); //Den Wert auf den Seriellen Monitor ausgeben
  Serial.println("cm"); //Der geschriebenen Zeile "cm" anfügen und einen Zeilenumbruch ausführen.
}

Download des Sketches

Hier nun der Sketch / das Programm zum bequemen Download:

Test der Reichweite

Nachdem nun die Schaltung aufgebaut ist möchte ich die beiden Sensoren einmal gegeneinander testen. Ich habe dazu einen sehr minimalistischen Aufbau mit einem Zollstock vorbereitet. 

Man erkennt auf dem Bild jedoch sehr gut das beide Sensoren nicht gerade genau sind, jedoch ist der Ultraschall Abstandssensor HC-SR04 etwas besser als wie der Laser Distanzsensor.

Video

Fazit

Als Fazit zu diesem Vergleich ziehe ich das beide Sensoren nicht gerade genau sind, daher würde ich beide nicht für das Zentimeter oder sogar Millimeter genaue messen verwenden wollen. Aber um ein Objekt zu detektieren oder zu erkennen das man x Zentimeter von einem anderen Objekt entfernt ist und somit ausweichen sollte reicht es allemal.

Den Ultraschall Abstandssensor HC-SR04 habe ich zbsp. im OTTO DIY Roboter verbaut und dort verrichtet dieser kleine Sensor sicher seinen Dienst.