eine digitale Wasserwaage mit dem M5StickC

In diesem Beitrag möchte ich dir zeigen wie du mit dem 6 Achsenlagesensor welche im M5StickC verbaut ist eine digitale Wasserwaage bauen kannst.

Den M5StickC habe ich bereits im Beitrag M5StickC – Ein ESP32 Zwerg mit nützlichen onboard Funktionen in einem coolen Gehäuse ausgiebig vorgestellt. Mehr wirst du für den Nachbau des Beitrages nicht benötigen. Okay ein

der 6 Achsenlagesensor am M5StickC vom Typ MPU6886

Der M5StickC hat einen 6 Achsenlagesensor vom Typ MPU6886 verbaut welchen ich in diesem Beitrag verwenden möchte. 

ein Beispiel

Wenn du die M5StickC Bibliothek installiert hast, dann findest du unter “Beispiele” > “M5StickC” > “Basics” > “MPU6886” ein ausführliches Beispiel. Leider ist dieses Beispiel nicht kommentiert, jedoch sind die Funktionen / Variablen sehr gut benannt somit ist dieser durchaus auch für Anfänger gut lesbar.

#include <M5StickC.h>

float accX = 0;
float accY = 0;
float accZ = 0;

float gyroX = 0;
float gyroY = 0;
float gyroZ = 0;

float temp = 0;
void setup() {
  // put your setup code here, to run once:
  M5.begin();
  M5.Lcd.setRotation(3);
  M5.Lcd.fillScreen(BLACK);
  M5.Lcd.setTextSize(1);
  M5.Lcd.setCursor(40, 0);
  M5.Lcd.println("MPU6886 TEST");
  M5.Lcd.setCursor(0, 15);
  M5.Lcd.println("  X       Y       Z");
  M5.MPU6886.Init();
}

void loop() {
  // put your main code here, to run repeatedly:
  M5.MPU6886.getGyroData(&gyroX,&gyroY,&gyroZ);
  M5.MPU6886.getAccelData(&accX,&accY,&accZ);
  M5.MPU6886.getTempData(&temp);

  M5.Lcd.setCursor(0, 30);
  M5.Lcd.printf("%.2f   %.2f   %.2f      ", gyroX, gyroY,gyroZ);
  M5.Lcd.setCursor(140, 30);
  M5.Lcd.print("o/s");
  M5.Lcd.setCursor(0, 45);
  M5.Lcd.printf("%.2f   %.2f   %.2f      ",accX * 1000,accY * 1000, accZ * 1000);
  M5.Lcd.setCursor(140, 45);
  M5.Lcd.print("mg");
  M5.Lcd.setCursor(0, 60);
  M5.Lcd.printf("Temperature : %.2f C", temp);
  delay(100);
}

In diesem Beispiel werden nicht nur die 6 Achsen ausgewertet sondern man erhält auch zusätzlich die Temperatur.

Da sich der Temperatursensor jedoch

• im Gehäuse,
• nahe am ESP32 Chip

befindet ist der Wert sehr Ungenau. Jedoch kann man diesen nutzen um die Temperatur des M5StickC im blick zu haben.

Exkurs: Aufbau einer Wasserwaage

Eine Wasserwaage ist ein Messgerät um Objekte waagerecht oder senkrecht auszurichten.
Zum ausrichten der Objekte wird eine Libelle verwendet welche zu den Kanten hin ausgerichtet ist.

Die Libelle selber ist eine Blase innerhalb einem mit Flüssigkeit gefüllten Gehäuse. An diesem Gehäuse sind zwei Markierungen angebracht in welche die Blase ausgerichtet wird um das Objekt korrekt auszurichten.

Möchtest du mehr über die Wasserwaage lesen  so möchte ich dir den nachfolgenden Wikipedia Artikel empfehlen.

Seite „Wasserwaage“. In: Wikipedia, Die freie Enzyklopädie. Bearbeitungsstand: 2. Mai 2020, 08:15 UTC. URL: https://de.wikipedia.org/w/index.php?title=Wasserwaage&oldid=199520605 (Abgerufen: 25. August 2020, 14:48 UTC)

Layout des LCD Displays für die Wasserwaage

Zunächst schreiben wir ein Sketch für das Layout auf dem Display. Wir benötigen zwei senkrechte Striche und ein Oval welches unsere Blase in der Libelle darstellen soll. Als Hintergrundfarbe nehmen wir ein grün Ton.

#include <M5StickC.h>

void setup() {
 //bleibt leer
}

void loop() {
  M5.begin();
  M5.Lcd.setRotation(3);
  M5.Lcd.fillScreen(GREEN);

  M5.Lcd.drawLine(50,0,50,80, BLACK);
  M5.Lcd.drawLine(110,0,110,80, BLACK);

  M5.Lcd.fillCircle(80, 40, 28, WHITE);
  
  delay(500);
}

Die möglichen Werte für die Farben findest du in der Datei “ST7735_Defines.h”.

#define BLACK               0x0000      /*   0,   0,   0 */
#define NAVY                0x000F      /*   0,   0, 128 */
#define DARKGREEN           0x03E0      /*   0, 128,   0 */
#define DARKCYAN            0x03EF      /*   0, 128, 128 */
#define MAROON              0x7800      /* 128,   0,   0 */
#define PURPLE              0x780F      /* 128,   0, 128 */
#define OLIVE               0x7BE0      /* 128, 128,   0 */
#define LIGHTGREY           0xC618      /* 192, 192, 192 */
#define DARKGREY            0x7BEF      /* 128, 128, 128 */
#define BLUE                0x001F      /*   0,   0, 255 */
#define GREEN               0x07E0      /*   0, 255,   0 */
#define CYAN                0x07FF      /*   0, 255, 255 */
#define RED                 0xF800      /* 255,   0,   0 */
#define MAGENTA             0xF81F      /* 255,   0, 255 */
#define YELLOW              0xFFE0      /* 255, 255,   0 */
#define WHITE               0xFFFF      /* 255, 255, 255 */
#define ORANGE              0xFD20      /* 255, 165,   0 */
#define GREENYELLOW         0xAFE5      /* 173, 255,  47 */
#define PINK                0xF81F

Programmieren einer digitalen Wasserwaage mit dem M5StickC

Nachdem wir das Layout für die digitale Wasserwaage definiert und programmiert haben möchten wir nun die X Achse des 6 Achsenlagesensors auswerten um die “Blase” nach rechts bzw. links zu bewegen.

#include <M5StickC.h>

//Variablen für die aktuelle Position 
float accX = 0;
float accY = 0;
float accZ = 0;

void setup() {
  M5.begin(); //beginn der Kommunikation mit dem M5StickC
  M5.Lcd.setRotation(3); //drehen des Displays um 90°
  M5.MPU6886.Init(); //beginn der Kommunikation mit dem 6 Achsenlagesensor MPU6886
}

void loop() {
  //Hintergrundfarbe "grün"
  M5.Lcd.fillScreen(GREEN);
  //aufrufen der Funktion zum setzen der Blase
  posCircle();
  //Zeichnen der Striche
  M5.Lcd.drawLine(50, 0, 50, 80, BLACK);
  M5.Lcd.drawLine(110, 0, 110, 80, BLACK);
  delay(250); //eine kleine Pause von 250ms
}

//Diese Funktion setzt einen Kreis an der Position auf dem Display,
//es wird die aktuelle Y Position des 6 Achsenlagesensors gelesen und 40 drauf addiert.
void posCircle() {
  M5.MPU6886.getAccelData(&accX, &accY, &accZ);
  int posY = round(accY * 1000) + 40;
  M5.Lcd.fillCircle(posY, 40, 28, WHITE);
}

Download

Hier nun der Sketch / das Programm zum bequemen download.

eine digitale Wasserwaage mit dem M5StickC 34 downloads 0.87 KB

Download