In diesem Tutorial möchte ich das Fan Motor Shield vorstellen.
Bezug
Das Fan Motor Shield habe ich bei ebay.de für ca. 2,5 € inkl. Versandkosten erstanden. Hier gibt es sehr große Preisunterschiede (8,99 € bis 2,52 €) für das gleiche Shield.
Lieferumfang
Zum Lieferumfang gehört:
- das Shield (inkl. Motor),
- ein Rotor,
- eine Rotorabdeckung
Technische Daten des Fan Motor Shield
- Rotordurchmesser 7,5 cm
- Betriebsspannung 5V
Anschluss & Schaltung
Das Shield verfügt über 4 Pins welche mit GND, VCC, INA, INB beschriftet sind.
Der Pin GND wird mit GND des Arduinos verbunden, der Pin VCC mit 5V und die Pins INA sowie INB mit digitalen PWM Pins.
Quellcode
Hier möchte ich nun ein einfaches Beispiel zeigen.
Einfaches Beispiel mit einem Drehpotentiometer
#define POTENTIOMETER A0 //Drehpotentiometer am analogen Pin A0
//Für das FAN Motor Shield werden jeweils PWM Pins benötigt!
#define FAN_INA 5 //Pin INA am digitalen PWM Pin D5
#define FAN_INB 6 //Pin INB am digitalen PWM Pin D6
//Konstanten für die Drehrichtung des Motors
const int REVERSE = 1; //Rückwärts
const int FORWARD = 2; //Vorwärts
//letzte gepeichterte Drehgeschwindigkeit des
//Motors
int lastFanSpeed =0;
void setup() {
Serial.begin(9600); //beginn der seriellen Kommunikation mit 9600 Baud
pinMode(FAN_INA,OUTPUT); //setzen des digitalen Pins INA für den Motor als Ausgang
pinMode(FAN_INB,OUTPUT); //setzen des digitalen Pins INB für den Motor als Ausgang
}
void loop() {
//lesen des aktuellen Wertes vom Drehpotentiometer
int fanSpeed = readPWMvalue();
//Wenn sich der Wert geändert hat dann....
if(lastFanSpeed != fanSpeed){
//merken der neuen Drehgeschwindigkeit
lastFanSpeed = fanSpeed;
//setzen der neuen Drehgeschwindigkeit
rotate(FORWARD, fanSpeed);
}
delay(250);
}
/**
* Lesen & Mappen des Wertes vom Drehpotentiometer
*/
int readPWMvalue(){
//lesen des analogen Wertes.
int analogValue = analogRead(POTENTIOMETER);
//Der analoge Wert liegt im Wertebereich von 0 bis 1023
//für den Motor wird ein PWM Signal benötigt dieses liegt jedoch
//im Wertebereich von 0 bis 255 daher muss dieses gemappt werden.
int pwmValue = map(analogValue, 0,1023, 0,245);
//Hier wird nicht auf 255 (max) gemappt sondern bis max 245
//das liegt daran das ein Fehler passiert wenn man das maximum des
//Motors erreicht.
return pwmValue;
}
/**
* Bewegen des Motors
* fanDirection - die Drehrichtung
* fanSpeed - die Drehgeschwindigkeit
*/
void rotate(int fanDirection, int fanSpeed){
int pwmValueINA = 0;
int pwmValueINB = 0;
if(fanDirection == REVERSE){
pwmValueINA = 0;
pwmValueINB = fanSpeed;
} else if(fanDirection == FORWARD){
pwmValueINA = fanSpeed;
pwmValueINB = 0;
}
analogWrite(FAN_INA, pwmValueINA);
analogWrite(FAN_INB, pwmValueINB);
}
Um nun den Rotor auch Rückwärts und Vorwärts laufen zu lassen kann man dieses auf zwei Wege erledigen. Entweder es wird ein Taster verwendet und dieser gibt ein Signal für die Richtungsänderung oder aber man nutzt den Wert vom Drehpotentiometer, dieser kann von 0 bis 1023 liegen (analog) wenn man also nun bei ca. 500 einen Cut macht und bestimmt das die Werte von 0 bis 500 Rückwärts und von 501 bis 1023 Vorwärts gelten. Zusätzlich müsste man bei der Lösung aber noch die Werte jeweils mappen.
