Arduino Lektion 40: Drehregler KY-040

Der Drehregler KY-040 ist ein Drehbarer Taster welcher in einzelne Schritte schaltet, dabei kann die aktuelle Position ausgelesen werden.

Jedesmal wenn der Arduino einen Reset erfährt geht die aktuelle Position verloren und es wird auf den Wert “0” zurück gesetzt.

Technische Daten

• Betriebsspannung 5V
• Maße 25mm x 13mm x 33mm
• Achse
  • Durchmesser 6mm (abgeflacht)
  • Länge 10mm

Schaltplan

Als Projekt habe mir überlegt dass, der Drehregler den Wert Binärcodiert anzeigen soll. D.h. ich verwende 8 LEDs wobei jede LED für ein Bit steht. Somit kann ich mit 8 LEDs = 8Bit = Zahlenbereich von 0 bis 255 Zahlen darstellen.

Was wird für diesen Aufbau benötigt?

Für diese Schaltung werden folgende Bauelemente benötigt. Die LEDs können selbstverständlich frei gewählt werden, dabei ist zu berücksichtigen das ggf. der Widerstandswert angepasst werden muss. Möchte man hier statt 8 LEDs mehr verwenden so sollte auf einen Arduino Mega zurückgegriffen werden dieser verfügt über 54 digitale PINs das bedeutet das mit dem Board (abzüglich der zwei PINs für den Drehregler) 52Bit angezeigt werden kann.

• Drehregler KY-040
• 8 LEDs, 5mm, blau
• 8 Widerstände, 220 Ohm
• Breadboard (min. 400 PIN)
• Breadboardkabel
• Arduino UNO

Quellcode

Mit dem nachfolgenden Code möchte ich nun die aktuelle Position mit Hilfe von 8 LEDs als Binärwert darstellen.

const int CLK = 3;  // CLK PIN des Drehreglers auf den digitalen PIN 3
const int DT = 4;  // DT PIN des Drehreglers auf den digitalen PIN 4

//LEDs für das darstellen
//der aktuellen Position als 
//Binärwert.
const int LED_8 = 6;
const int LED_7 = 7;
const int LED_6 = 8;
const int LED_5 = 9;
const int LED_4 = 10;
const int LED_3 = 11;
const int LED_2 = 12;
const int LED_1 = 13;

//Variablen zum Speichern
//der aktuellen Position, sowie
//der letzen Position
int posCount = 0; 
int lastPosition;  
int currentPosition;

void setup() { 
   //Setzen des Drehreglers als Eingangssignal
   pinMode (CLK,INPUT);
   pinMode (DT,INPUT);

   //Setzen des LEDs als Ausgangssignal
   pinMode (LED_8,OUTPUT);
   pinMode (LED_7,OUTPUT);
   pinMode (LED_6,OUTPUT);
   pinMode (LED_5,OUTPUT);
   pinMode (LED_4,OUTPUT);
   pinMode (LED_3,OUTPUT);
   pinMode (LED_2,OUTPUT);
   pinMode (LED_1,OUTPUT);

   //Speichern des aktuellen Wertes ("0")
   lastPosition = digitalRead(CLK);   
   //Beginn der seriellen Kommunikation mit 9600 baud.
   Serial.begin (9600);
 } 

 void loop() {
   //lesen des aktuellen Wertes
   currentPosition = digitalRead(CLK);
   //Wenn die aktuelle Position ungleich der letzten Position ist dann...
   if (currentPosition != lastPosition){
    //Wenn die neue Position größer als die aktuelle Position ist dann
    //die Variable posCount um eins ("1") erhöhen, ansonsten
    //die Variable posCount um eins ("1") verringern.
    (digitalRead(DT) != currentPosition)?posCount ++:posCount--;

    //Ausgabe der aktuellen Position auf den seriellen Schnittstelle. 
    Serial.print("Position: ");
    Serial.println(posCount);
    //Darstellen der aktuellen Position als Binärwert mit den LEDs.
    displayNumber();
   }
   lastPosition = currentPosition;
 }

/*
 * Stellt den Wert posCount als Binärwert 
 * mit den LEDs dar.
 * Es können Werte von 0 bis 255 dargestellt werden. (8Bit)
 */
void displayNumber(){
  //Umwandeln der Ganzzahl in Binär.
  String bitValue = String(posCount, BIN); 
  //Ermitteln der Stellen um welche auf 8Bit aufgefüllt werden muss.
  int numLeadingZeros = (8 - bitValue.length());
  //Wenn kleiner als 8Bit dann mit führenden nullen ("0") auffüllen.
  String result = "";
  for(int i=0;i<numLeadingZeros;i++){
   result += "0";
  }
  result += bitValue;
  //Für jede Stelle in dem Binärwert...
  for(int b=0;b<result.length();b++){
    char c = result.charAt(b);
    //Wenn die aktuelle Position eine 1 ist dann die LED einschalten
    //ansonsten ausschalten.
    digitalWrite(b+6, c == '1' ? HIGH : LOW);
  }
}

Der Drehregler KY-040 verfügt auch über einen Taster welcher über den PIN “SW” angeschlossen werden kann.

Video