In diesem Beitrag stelle ich einen Vergleich der beiden Sensoren BMP280 & BMP180 auf und zeige dir die Unterschiede bei der Genauigkeit sowie ggf. der Programmierung am Mikrocontroller.
Den Sensor BMP180 habe ich bereits in den nachfolgenden Beiträgen behandelt und gezeigt wie dieser am Mikrocontroller der Arduino-Familie programmiert wird.
- Arduino Lektion 10: BMP180 digitaler Luftdruck Sensor
- Wemos D1 mini Shield: BMP180 Shield
- DIY Wetterstation v2.0
Preisvergleich
Beide Sensoren bekommst du auf diversen Plattformen recht günstig. Bei Bestellungen von aliexpress.com muss man immer eine lange Lieferzeit einrechnen. Jedoch bekommt man dort die Bauteile dort am günstigsten.
| Shop | BMP180 | BMP280 |
|---|---|---|
| ebay.de | 1,29 € – 4,99 €* | 2,55 € – 4,49 €* |
| eckstein-shop.de | – | 2,55 € |
| amazon.de | 2,51 € – 14,82 €* | 5,99 € – 17,99 €* |
| aliexpress.com | 0,33 € – 0,66 € | 0,31 € – 1,75 € |
Hinweis von mir: Die mit einem Sternchen (*) markierten Links sind Affiliate-Links. Wenn du über diese Links einkaufst, erhalte ich eine kleine Provision, die dazu beiträgt, diesen Blog zu unterstützen. Der Preis für dich bleibt dabei unverändert. Vielen Dank für deine Unterstützung!
Vergleich der technischen Daten vom BMP280 & BMP180
| BMP180 | BMP280 | |
|---|---|---|
| Betriebsspannung | 1,8 V – 3,6 V | 1,2 V – 3,6 V |
| Leistungsaufnahme | 12 µA | 2,7 µA |
| Genauigkeit | 1 Pa | 0,16 Pa |
| Messbereich | 300 hPa – 1100 hPa | 300 hPa – 1100 hPa |
| Temperaturgenauigkeit | 0,1 °C | 0,01 °C |
| Schnittstelle | I²C | I²C, SPI |
| Abmaße (L x B) | 14 mm x 14 mm | 13 mm x 10 mm |
Der Sensor BMPx80 ist von Firma Bosch und diese liefert ein PDF Dokument zu den technischen Spezifikationen, welches du unter BMP280 – Digital Pressure Sensor, in welchem du weitere, technische Informationen zu diesem Sensor findest.
Die Betriebsspannung der Sensoren bezieht sich unter Umständen „nur“ auf den verbauten Chip von der Firma Bosch. Wenn du ein fertiges Shield kaufst, dann musst du prüfen, welche Versorgungsspannung dort verlangt wird.
Genauigkeit der Sensorwerte
In den technischen Daten ist die Genauigkeit beim Messen des atmosphärischen Drucks beim BMP180 auf 1 Pascal und beim BMP280 auf 0,16 Pa angegeben. Der BMPx80 Sensor liefert auch die Temperatur, welche mit einer Genauigkeit von 0,1 °C beim BMP180 und beim BMP280 0,01 °C angegeben.
Programmieren der Sensoren in der Arduino IDE
Für die Sensoren gibt es von Adafruit jeweils eine Bibliothek für die Arduino IDE.
- BMP180 – https://github.com/adafruit/Adafruit-BMP085-Library
- BMP280 – https://github.com/adafruit/Adafruit_BMP280_Library
Wie du eine Bibliothek in der Arduino IDE einbindest habe ich dir im gleichnamigen Beitrag Arduino IDE, Einbinden einer Bibliothek erläutert.
Beispiele aus den Bibliotheken
Bei beiden Bibliotheken sind jeweils Beispiele vorhanden, wobei ich beim BMP280 eine kleine Modifikation vornehmen musste. Denn mein Sensor läuft mit der Adresse 0x76 und der default in der Bibliothek ist 0x77.
/*!
* Initialises the sensor.
* @param addr
* The I2C address to use (default = 0x77)
* @param chipid
* The expected chip ID (used to validate connection).
* @return True if the init was successful, otherwise false.
*/
bool Adafruit_BMP280::begin(uint8_t addr, uint8_t chipid) {...}Wenn dein Sensor nicht erkannt wird, kannst du mit dem I²C Scanner ggf. einmal deine angeschlossenen I²C Sensoren prüfen und die korrekte Adresse herausfinden.
Anschluss der Sensoren am Arduino UNO
Da beide Sensoren per I²C programmiert werden, können wir diese in einer Schaltung am Arduino UNO anschließen. In meinem Fall nutze ich den Keyestudio UNO R3 welcher gesonderte Pins für SDA & SCL hat. Beim normalen Arduino UNO R3 findest du die I²C Pins an den analogen Pins A4 & A5.
Sketch zum Auslesen der Sensoren
//Bibliotheken für den BMP280
#include <Wire.h>
#include <SPI.h>
#include <Adafruit_BMP280.h>
//Bibliothek für den BMP180
#include <Adafruit_BMP085.h>
//Initialisieren des BMP280 Sensors
Adafruit_BMP280 bmp280;
Adafruit_Sensor *bmp_temp = bmp280.getTemperatureSensor();
Adafruit_Sensor *bmp_pressure = bmp280.getPressureSensor();
//Initialisieren des BMP180 Sensors
Adafruit_BMP085 bmp180;
void setup() {
//beginn der seriellen Kommunikation mit 9600 baud
Serial.begin(9600);
//warten auf die serielle Verbindung
while ( !Serial ) delay(100);
//prüfen ob die Kommunikation mit den Sensoren aufgebaut werden kann.
bool error = false;
if (!bmp180.begin()) {
Serial.println("Fehler beim lesen der BMP180 Sensors!");
error = true;
}
if (!bmp280.begin(0x76)) {
Serial.println("Fehler beim lesen des BMP280 Sensors!");
error = true;
}
//Wenn einer der Sensoren nicht gefunden wurde,
//dann soll die Verarbeitung der Funktion "loop" unterbunden werden.
if (error) {
Serial.print("Fehler");
while (true) {
Serial.print(".");
}
}
//Einstellungen für den BMP280 Sensor (aus dem Beispiel der Bibliothek entnommen)
/* Default settings from datasheet. */
bmp280.setSampling(Adafruit_BMP280::MODE_NORMAL, /* Operating Mode. */
Adafruit_BMP280::SAMPLING_X2, /* Temp. oversampling */
Adafruit_BMP280::SAMPLING_X16, /* Pressure oversampling */
Adafruit_BMP280::FILTER_X16, /* Filtering. */
Adafruit_BMP280::STANDBY_MS_500); /* Standby time. */
//Spaltenkopf
Serial.println("BMP180\t\t\t|BMP280");
}
void loop() {
//Ausgeben der Daten vom BMP180 Sensor
readBmp180();
//Tabulator inkl. Pipe als trenner
Serial.print("\t|");
//Ausgeben der Daten vom BMP280 Sensor
readBmp280();
//Zeilenende
Serial.println("");
//eine kleine Pause von 2 Sekunden
delay(2000);
}
void readBmp180() {
Serial.print(bmp180.readTemperature());
Serial.print(" *C");
Serial.print(" | ");
//Die ausgabe erfolgt in Pascal,
//daher wird der Wert durch 100 geteilt
Serial.print(bmp180.readPressure() / 100);
Serial.print(" hPa");
}
void readBmp280() {
sensors_event_t temp_event, pressure_event;
bmp_temp->getEvent(&temp_event);
bmp_pressure->getEvent(&pressure_event);
Serial.print(temp_event.temperature);
Serial.print(" *C");
Serial.print(" | ");
Serial.print(pressure_event.pressure);
Serial.print(" hPa");
}
Im nachfolgenden Screenshot erkennst du, dass der BMP180 bei der Temperatur eine sehr große Differenz zum BMP280 aufweist. Der atmosphärische Druck wird beim BMP180 ohne Nachkommastellen angezeigt.
Fazit
Als Fazit ziehe ich, dass der BMP280 eine Alternative zum deutlich ungenauen BMP180 ist jedoch müsste man die Sensorwerte in einem Labor validieren, um wirklich genau zu sagen, welcher Sensor am ungenauesten ist.
Da der Preis für diese Sensoren auf aliexpress.com doch recht günstig ist, kann man sich diesen kleinen Sensor für Wetterstationen etc. in der Version BMP280 gönnen. Natürlich gibt es deutlich genauere Sensoren, jedoch kosten diese deutlich mehr.