ESP32 mit DHT11, kapazitiven Bodenfeuchtesensor – Teil 2

In diesem zweiten Teil zum ESP32 Baustein mit DHT11 & kapazitiven Bodenfeuchtesensor möchte ich dir zeigen, wie du diesen autark betreiben kannst.

Mikrocontroller ESP32 autark über LiPo Batterie betreiben
Mikrocontroller ESP32 autark über LiPo Batterie betreiben

Was bedeutet autark Betreiben?

Der hier verwendete ESP32 Baustein kann eine LiPo Batterie vom Typ 18650 auf der Rückseite aufnehmen.

ESP32 Baustein & LiPo Batterie 18650
ESP32 Baustein & LiPo Batterie 18650

Über diese Batterie kann der Mikrocontroller mehrere Stunden betrieben werden. Damit dieser jedoch deutlich länger durchhält, müssen wir diesen in einen Schlafmodus versehen und immer wieder (in einem Intervall) erwecken.

Wenn der Mikrocontroller aus dem Schlaf erweckt wurde, dann werden diese Daten an ThingSpeak gesendet und der Mikrocontroller geht wieder für eine Zeit x in den sogenannten DeepSleep.

Mikrocontroller in den DeepSleep versetzen und erwecken

Wie du einen Mikrocontroller vom Typ ESP8266 in den DeepSleep versetzt, habe ich dir bereits im Beitrag NodeMCU – Deep Sleep des ESP8266 gezeigt. Am ESP32 ist dieses etwas einfacher, denn diese Verbindungen sind bereits intern verdrahtet und somit entfällt eine solche Verbindung.

void setup() {
  //beginn der seriellen Kommunikation mit 115200 baud
  //Es könnte auch jeder andere gültige Wert gewählt werden,
  //jedoch wird über diesen Wert auch die Debugausgaben angezeigt
  Serial.begin(115200);
  //Timeout für die serielle Verbindung
  Serial.setTimeout(2000);
  //solange die serielle Schnittstelle nicht bereit ist, mache... (nix)
  while(!Serial) { }
  //Ausgabe des Textes inkl. der Millisekunden seit dem der Microcontroller gestartet ist.
  Serial.print("Hallo, ich bin wach. Der Microcontroller läuft seit ");
  Serial.print(millis());
  Serial.println(" Millisekunden.");
  Serial.println("Ich gehe gleich für 10 sek. in den Deep Sleep.");
  //den Microcontroller in den Deep Sleep für 10 Sekunden versetzen.
  ESP.deepSleep(10e6); 
}
void loop() {
  //bleibt leer
}

Die Ausgabe auf der seriellen Schnittstelle, sieht dann wiefolgt aus:

rst:0x5 (DEEPSLEEP_RESET),boot:0x13 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:1
load:0x3fff0030,len:1240
load:0x40078000,len:13012
load:0x40080400,len:3648
entry 0x400805f8
Hallo, ich bin wach. Der Microcontroller läuft seit 10 Millisekunden.
Ich gehe gleich für 10 sek. in den Deep Sleep.

Neben den Zeichenketten aus dem Code (Serial.print / Serial.println) werden auch Debugausgaben angezeigt, welche darauf deuten, dass der ESP neu gestartet ist.

Senden der Daten an ThingSpeak

Den IoT Dienst ThingSpeak habe ich bereits in einigen Beiträgen verwendet:

Dieser Dienst ist zum einen kostenfrei und zum anderen recht easy zu verwenden.

#include "DHT.h"
#include <WiFi.h>
#include <HTTPClient.h>

#define DHT11PIN 22
#define DHT11TYPE DHT11
DHT dht11(DHT11PIN, DHT11TYPE);

#define BODENFEUCHTE_SENSOR_PIN 32

const char* ssid = ""; //SSID aus dem Router
const char* password = ""; //Passwort für den Zugang zum WLAN

String url = "http://api.thingspeak.com/update?api_key=3BEQQUDGMFS130A7";

HTTPClient http;

void setup() {
  Serial.begin(115200);
  dht11.begin();

  WiFi.begin(ssid, password);
}

void loop() {
  float humidy = dht11.readHumidity();
  float temp = dht11.readTemperature();
  int bodenfeuchte = analogRead(BODENFEUCHTE_SENSOR_PIN);

  if (isnan(humidy) || isnan(temp) || isnan(bodenfeuchte)) {
    Serial.println("Fehler beim lesen der Sensordaten!");
  } else {
    sendDhtData(url, temp, humidy, bodenfeuchte);
  }
  delay(3500);
}

void sendDhtData(String ineturl, float tempValue, float humidityValue, int bodenfeuchte) {
  String url = ineturl + "&field1=" + tempValue + "&field2=" + humidityValue + "&field3=" + bodenfeuchte;

  http.begin(url);
  Serial.print(millis());

  int httpCode = http.GET();
  Serial.print("\t");
  Serial.print(httpCode);
}

Im obigen Sketch werden die Daten alle 3,5 Sekunden an den IoT Dienst ThingSpeak gesendet.

In ThingSpeak habe ich pro Sensorwert ein Liniendiagramm konfiguriert. Welches die Daten anzeigt.

ThingSpeak & Deep Sleep

Im nächsten Schritt möchte ich dir zeigen, wie man den Mikrocontroller in einen Deep Sleep versetzt, nach 5 Minuten erweckt und die Daten an ThingSpeak sendet.

#include "DHT.h"
#include <WiFi.h>
#include <HTTPClient.h>

#define DHT11PIN 22
#define DHT11TYPE DHT11
DHT dht11(DHT11PIN, DHT11TYPE);

#define BODENFEUCHTE_SENSOR_PIN 32

#define uS_TO_S_FACTOR 1000000ULL
#define TIME_TO_SLEEP  300       

RTC_DATA_ATTR int bootCount = 0;

const char* ssid = ""; //SSID aus dem Router
const char* password = ""; //Passwort für den Zugang zum WLAN

String url = "http://api.thingspeak.com/update?api_key=3BEQQUDGMFS130A7";

HTTPClient http;

void setup() {
  Serial.begin(115200);
  delay(1000); //Take some time to open up the Serial Monitor

  //Increment boot number and print it every reboot
  ++bootCount;
  Serial.println("Boot number: " + String(bootCount));

  WiFi.begin(ssid, password);

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    Serial.print(".");
  }

  Serial.println("");
  Serial.print("Erfolgreich verbunden zu ");
  Serial.println(ssid);
  Serial.print("IP Adresse: ");
  Serial.println(WiFi.localIP());

  dht11.begin();

  float humidy = dht11.readHumidity();
  float temp = dht11.readTemperature();
  int bodenfeuchte = analogRead(BODENFEUCHTE_SENSOR_PIN);

  if (isnan(humidy) || isnan(temp) || isnan(bodenfeuchte)) {
    Serial.println("Fehler beim lesen der Sensordaten!");
  } else {
    url = url + "&field1=" + temp + "&field2=" + humidy + "&field3=" + bodenfeuchte;
    Serial.print("Adresse: ");
    Serial.println(url);

    http.begin(url);
    Serial.print("Time: ");
    Serial.println(millis());

    int httpCode = http.GET();
    Serial.print("HTTP-Code: ");
    Serial.print(httpCode);
    Serial.print(" Fehlermeldung: ");
    Serial.println(http.errorToString(httpCode).c_str());
    http.end();
  }

  esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP * uS_TO_S_FACTOR);
  Serial.println("Nun gehts schlafen für 5min.");
  Serial.flush();
  esp_deep_sleep_start();
}

void loop() {
  //This is not going to be called
}

Kommentar hinterlassen

Deine E-Mail-Adresse wird nicht veröffentlicht.