Arduino Lektion 42: TM1638 LED Taster Shield

Das „TM1638 LED Taster Shield“ verfügt über

• 8 LED,
• 8 Taster, sowie
• 2 4fach 7 Segment LED Anzeigen

Das Shield wird über einen TM1638 Chip betrieben.

Das Shield wird vormontiert geliefert, jedoch war auf der Oberseite eine weiße, schmierige, Klebriege Flüssigkeit welche ich mit einem Brillenputztuch entfernen konnte.

Technische Daten des TM1638

• Betriebsspannung 5V

Anschlussplan

Das Shield verfügt über 5 Pins welche wie folgt an den Maker UNO angeschlossen werden:

• VCC – 5V
• GND – GND
• STB – digitaler PIN D8
• CLK – digitaler PIN D9
• DIO – digitaler PIN D10

Der Maker UNO verfügt über einen Piezo Buzzer welcher am digitalen Pin D8 angeschlossen ist, für diesen Aufbau musste ich also den Piezo Buzzer auf Mute stellen.

Bezug

Das Shield kann über ebay.de*, amazon.de* oder banggood.com für ca. 4 € bezogen werden.

Hinweis von mir: Die mit einem Sternchen (*) markierten Links sind Affiliate-Links. Wenn du über diese Links einkaufst, erhalte ich eine kleine Provision, die dazu beiträgt, diesen Blog zu unterstützen. Der Preis für dich bleibt dabei unverändert. Vielen Dank für deine Unterstützung!

Schaltung

Für den Aufbau der Schaltung verwende ich den Maker UNO und habe mir noch zusätzlich ein kleines Stativ gebaut damit das Shield in einem besseren Winkel steht.

Quellcode

Bibliothek

Für das Shield gibt es eine komfortable Bibliothek welche vom GitHub Repository https://github.com/rjbatista/tm1638-library geladen werden kann.

Wie eine Bibliothek der Arduino IDE hinzugefügt wird habe ich im Tutorial Arduino IDE, Einbinden einer Bibliothek erläutert.

Interaktionen mit den Tastern

Die Taster sind binär codiert d.h. der erste Taster hat den Code 1, der zweite die 2 der dritte die 4 usw.

Mit der Funktion „getButtons()“ erhält man nun eine Zahl und wenn zwei (oder mehr) Tasten gedrückt wurden, dann erhält man eine addierte Zahl.

Beispiel

Taste 1 (1) & Taste 2 (2) wurde zusammen gedrückt, dadurch wird nun der Wert „3“ zurückgegeben.

#include "TM1638.h"

const int STB = 8;
const int CLK = 9;
const int DIO = 10;

TM1638 modul(DIO, CLK, STB);

void setup(){
  //bleibt leer
}

void loop(){
  byte button = modul.getButtons(); 
  modul.setDisplayToDecNumber(button, 0b00000000, false);
}

Interaktionen mit den LEDs

Das Shield verfügt neben den 8 Tasten auch über 8 LEDs welche einzeln angesprochen werden können.

Beispiel

Im folgenden Beispiel möchte ich nun die 8 Taster verwenden, um jeweils die gegenüberliegende LED aufleuchten zu lassen.

#include "TM1638.h"

const int STB = 8;
const int CLK = 9;
const int DIO = 10;
const int LED_MASK = 0xFF;

const int MAX_NUM_LED = 8;
int leds[MAX_NUM_LED] = {1,2,4,8,16,32,64,128};

TM1638 modul(DIO, CLK, STB);

void setup(){
  //bleibt leer
}

void loop(){
  for(int i=0;i<=MAX_NUM_LED;i++){
    modul.setLEDs(leds[i]& LED_MASK);
    delay(250);
  }
}

Um alle LEDs wieder auszuschalten wird der Funktion „setLEDs()“ eine 0 übergeben.

Interaktion mit den 4fach 7 Segment LED Displays

Die 4fach 7Segment Displays können einfach mit den Funktionen aus der Bibliothek TM1638 angesprochen werden.

Es gibt neben der Bibliothek TM1638 auch die InvertedTM1638 diese manipuliert die LED Displays so, das die Ausrichtung umgekehrt ist. Je nachdem wie das Display später eingebaut werden soll, kann dieses nützlich sein.

Beispiel

#include "TM1638.h"
#include <InvertedTM1638.h>

const int STB = 8;
const int CLK = 9;
const int DIO = 10;
const int LED_MASK = 0xFF;

TM1638 modul(DIO, CLK, STB);

void setup(){
 //bleibt leer
}

void loop(){
    String text[5] = {"HALLO", "DIES", "IST", "EIN", "TEST"};
    for(int i=0;i<=5;i++){
      modul.clearDisplay();
      modul.setDisplayToString(text[i]);  
      delay(750);
    }
}

Bei der Ausgabe eines Textes auf dem 4fach 7Segment Display ist empfehlenswert alle Buchstaben in GROßSCHRIFT zu übergeben. (Wie in dem Beispiel zu sehen.) Es können kleine Buchstaben übergeben werden, dieses ist aber nicht gerade gut zu lesen. Es werden aber bestimmte Buchstaben in kleine Buchstaben „umgewandelt“ da diese nicht anders dargestellt werden können (zbsp „T“ wird zu „t“).

Video

In diesem Video möchte ich die oben genannten Sketche einmal zeigen.

Die LED an der Position 1 war bei meinem Shield defekt somit musste ich diese austauschen.

Beispiel 1 – Temperatur, Luftfeuchtigkeit

Es soll über die Auswahl eines Taster verschiedene Werte der Sensoren auf den 4fach 7 Segment LED Anzeigen angezeigt werden.

Die Werte der Sensoren sollen wie folgt angezeigt werden:

• te. 25
• hu. 60

Als Sensor verwende ich den DHT11 Sensor welchen ich schon im Tutorial Arduino Lektion 6: Sensor DHT11, Temperatur und relative Luftfeuchtigkeit messen beschrieben habe.

Aufbau

Der DHT11 Sensor wird über den digitalen PIN D4 angeschlossen.

Quellcode

Da der DHT11 Sensor die Temperatur „nur“ auf 1 °C genau wiedergibt wandle ich den eigentlichen double (Gleitkommazahl) in einen Integer um somit wird mir die hier unnötige Nachkommastelle abgeschnitten.

#include "TM1638.h"
#include "DHT.h" //DHT Bibliothek

const int STB = 8;
const int CLK = 9;
const int DIO = 10;

#define DHTPIN 4 
#define DHTTYPE DHT11

DHT dht(DHTPIN, DHTTYPE);

byte selectedBtn = 2;

TM1638 modul(DIO, CLK, STB);

void setup(){
  Serial.begin(57600); 
  dht.begin();
}

void loop(){
  byte btn = modul.getButtons();
  if(btn != 0){
    selectedBtn = btn;
  }

 String text;
 word dots;
  
  switch(selectedBtn){
    case 1: text = getTemperatur(); dots = 0b01000000; break;
    case 2: text = getLuftfeuchtigkeit(); dots = 0b01000000; break;
    default: text = "Error"; dots = 0;
  }
    
  modul.clearDisplay();
  modul.setDisplayToString(text,dots);  
  
  delay(1000);
}

String getTemperatur(){   
  int temp = dht.readTemperature();
  String result = "";
  result += "te  ";
  result += temp;
  return result;
}

String getLuftfeuchtigkeit(){
  int luftfeuchtigkeit = dht.readHumidity();
  String result = "";
  result += "hu  ";
  result += luftfeuchtigkeit;
  return result;
}

Video

Beispiel 2 – Gedächnisstrainer

Ziel dieses Spieles ist es, eine vorgegebene Reihenfolge von aufleuchtenden LEDs über die Tasten wiederzugeben. Die beiden 4fach 7 Segment Displays dienen hierbei, um die Leben sowie die Punkte zu zählen.

Aufbau

Für dieses Beispiel verwende ich den Maker UNO welchen ich bereits im gleichnamigen Tutorial Maker UNO – Überblick und Test beschrieben habe. Ein Vorteil dieses Mikrocontrollers ist es, das dieser einen Piezo Buzzer sowie einen Taster (fest verbaut) mit bringt, somit wird für diese Schaltung nur das TM1638 Shield benötigt.

Wenn du dieses Beispiel mit einem „normalen“ Arduino UNO nachbauen möchtest, benötigst du:

• einen Taster
• einen 120 kOhm Widerstand
• einen Piezo Buzzer

In dieser Schaltung habe ich den Piezo Buzzer auf den digitalen Pin 8 und den Taster auf den digitalen Pin 2 gelegt, dieses sind auch die gleichen Pins auf welchem beim Maker UNO die Bauteile geschaltet sind.

Im Quellcode ist jedoch darauf zu achten das hier der INPUT_PULLUP entfällt da dieses durch den 120 kOhm Widerstand gelöst wurde.

Quellcode

#include "TM1638.h"

const int STB = 7;
const int CLK = 9;
const int DIO = 10;

TM1638 modul(DIO, CLK, STB);

const int MAX_LEDS = 8;
const int LED_MASK = 0xFF;

int pause = 1050;
const int OFFSET_PAUSE = 50;

const int BUZZER = 8;
const int RESET = 2;

int leben = 3;

void setup(){
  Serial.begin(9600);  //Übertragungsgeschwindigkeit 9600 Baud
  pinMode(BUZZER, OUTPUT);
  pinMode(RESET, INPUT_PULLUP);
  randomSeed(analogRead(0));
}

int leds[MAX_LEDS] = {1,2,4,8,16,32,64,128};

void loop(){
 if(leben > -1){
   modul.clearDisplay();  
   modul.setDisplayToDecNumber(leben,0b00000000,true);  
   playGame();
 } else {
   modul.setDisplayToString("Ende    ",0b00000000);   
   if(digitalRead(RESET)==LOW){
     leben = 3;
   }
 }
}

void playGame(){
 if(pause > 750){
   pause = pause - OFFSET_PAUSE;
 } 
 
 int rLeds[MAX_LEDS];
 
 //Aufbau der Zufallszahlen
 
 for(int i=0;i<MAX_LEDS;i++){
  int index = random(MAX_LEDS); 
  rLeds[i]= leds[index];
 }

 //Abspielen der Zufälligen LEDs
 for(int i=0;i<MAX_LEDS;i++){
  modul.setLEDs(rLeds[i] & LED_MASK);
  Serial.println(rLeds[i]);
  delay(pause);
   modul.setLEDs(0);
  delay(350);
 }
 
 playTone(500);

 int btn[MAX_LEDS];
 int index = 0;
 do{
   byte button = modul.getButtons(); 
   if(button >0){
     playTone(1400);
     modul.setLEDs(button & LED_MASK);
     btn[index] = button;
     index++;     
     delay(450);
   }   
 } while(index < 8);

 //Vergleichen der beiden Arrays
 //Wenn diese unterschiedlich sind dann ein Leben abziehen
 for(int i=0;i<MAX_LEDS;i++){
  int valLed = rLeds[i];
  int valBtn = btn[i];
  if(valLed != valBtn){
    playTone(400);
    playTone(200);
    leben--;
    break;
  }
 }
}

void playTone(int freq){
 tone(BUZZER, freq, 350);
}

Video

Beispiel 3 – Uhrzeit

In diesem Beispiel möchte ich die Uhrzeit auf dem Display wiedergeben. Leider verfügt das 4fach 7Segment LED Display „nur“ über einen Punkt und kein Doppelpunkt. Daher wird der Punkt als Trennzeichen genutzt.

Für dieses Beispiel wird neben einem Arduino UNO kompatiblen Mikrocontroller und dem TM1638 Shield auch ein DS3231 benötigt. Die RealTimeClock DS3231 habe ich im Tutorial Arduino Lektion 17: RealTimeClock RTC DS3231 bereits behandelt.

Aufbau

Quellcode

Als Trennzeichen für die Uhrzeit konnte ich hier nur (Bauartbedingt) einen Punkt statt ein Doppelpunkt nutzen.

#include "TM1638.h"
#include <Wire.h>
#define RTC_I2C_ADDRESS 0x68 // I2C Adresse des RTC  DS3231

const int STB = 8;
const int CLK = 9;
const int DIO = 10;

//Membervariablen
int jahr,monat,tag,stunde,minute,sekunde, wochentag;
int daysInMonth[12]={31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31};
String daysInWeek[7] = {"Sonntag", "Montag", "Dienstag", "Mittwoch", "Donnerstag", "Freitag", "Samstag"};
String monthInYear[12] = {"Januar","Februar", "März", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"};
String outputFormat = "%s, %02d.%s %04d %02d:%02d:%02d Uhr";

byte selectedBtn = 2;

TM1638 modul(DIO, CLK, STB);

void setup(){
   Wire.begin(); //Kommunikation über die Wire.h bibliothek beginnen.       
  Serial.begin(57600);  //Übertragungsgeschwindigkeit 57600 Baud
  Serial.println("Mit dem Befehl kann das Datum und die Uhrzeit gesetzt oder veraendert werden.");
  Serial.println("Beispiel: set 28.08.2013 10:54");
}

void loop(){
  byte btn = modul.getButtons();
  if(btn != 0){
    selectedBtn = btn;
  }

 String text;
 word dots;
  
  switch(selectedBtn){
    case 1: text = getRTCTime(); dots = 0b01010000; break;
    case 2: text = getRTCDate(); dots = 0b01010000; break;
    default: text = "Error"; dots = 0;
  }
    
  modul.clearDisplay();
  modul.setDisplayToString(text,dots);  
  
  setRTCTime();
  delay(1000);
}

 
//Ließt den aktuellen Zeitstempel aus dem RTC Modul.
void rtcReadTime(){
  Wire.beginTransmission(RTC_I2C_ADDRESS); //Aufbau der Verbindung zur Adresse 0x68
  Wire.write(0);
  Wire.endTransmission();
  Wire.requestFrom(RTC_I2C_ADDRESS, 7);
  sekunde    = bcdToDec(Wire.read() & 0x7f);
  minute     = bcdToDec(Wire.read()); 
  stunde     = bcdToDec(Wire.read() & 0x3f); 
  //Der Wochentag wird hier nicht ausgelesen da dieses mit 
  //dem Modul RTC DS3231 nicht über die Wire.h zuverlässig funktioniert.
  /* wochentag  =*/ bcdToDec(Wire.read());
  tag        = bcdToDec(Wire.read());
  monat      = bcdToDec(Wire.read());
  jahr       = bcdToDec(Wire.read())+2000;    
}
 
//Funktion zum schreiben / setzen der Uhrzeit.
void rtcWriteTime(int jahr, int monat, int tag, int stunde, int minute, int sekunde){
  Wire.beginTransmission(RTC_I2C_ADDRESS);
  Wire.write(0); // Der Wert 0 aktiviert das RTC Modul.
  Wire.write(decToBcd(sekunde));    
  Wire.write(decToBcd(minute));
  Wire.write(decToBcd(stunde));                                  
  Wire.write(decToBcd(0)); // Wochentag unberücksichtigt
  Wire.write(decToBcd(tag));
  Wire.write(decToBcd(monat));
  Wire.write(decToBcd(jahr-2000));  
  Wire.endTransmission();  
}
 
//Berechnet den Tag der Woche aus dem übergebenen Datumswerten.
byte calcDayOfWeek(int jahr, byte monat, byte tag) {
  static int t[] = {0, 3, 2, 5, 0, 3, 5, 1, 4, 6, 2, 4};
  jahr -= monat < 3;
  return ((jahr + jahr/4 - jahr/100 + jahr/400 + t[monat-1] + tag) % 7); 
}
 
//Convertiert Dezimalzeichen in binäre Zeichen.
byte decToBcd(byte val){
  return ( (val/10*16) + (val%10) );
}
 
//Convertiert binäre Zeichen in Dezimal Zeichen.
byte bcdToDec(byte val){
  return ( (val/16*10) + (val%16) );
}
 
//Ließt einen String und liefert einen Integer Wert von einer 
//definierten Stelle (byte num) des Stringwertes.
int getIntFromString (char *stringWithInt, byte num){
  char *tail; 
  while (num>0){
    num--;
    //Bei Kommanseparierten Listen werden die Kommata 
    //übersprungen und geben damit die Unterteilung des Strings an.
    while ((!isdigit (*stringWithInt))&&(*stringWithInt!=0)){
      stringWithInt++;
    }
    tail=stringWithInt;
    //Schleife solange ausführen bis eine Zahl gefunden wurde
    //welche größer 0 ist.
    while ((isdigit(*tail))&&(*tail!=0)){
      tail++;
    }
   
    if (num>0){
      stringWithInt=tail;
    }
  }  
  return(strtol(stringWithInt, &tail, 10));
}  
 
String getRTCTime(){
  rtcReadTime(); 
  String result = "";
  if(stunde<10) { result += "0"; }
  result += stunde;  
  if(minute<10) { result += "0"; }
  result += minute;  
  if(sekunde<10) { result += "0"; }
  result += sekunde;  
  return result; 
}

String getRTCDate(){
  rtcReadTime(); 
  String result = "";
  if(tag<10) { result += "0"; }
  result += tag;  
  if(monat<10) { result += "0"; }
  result += monat;  
  result += jahr;  
  return result; 
}
 
//Manuelles setzen der Uhrzeit über den Seriellen Monitor der IDE.
void setRTCTime(){
  char linebuf[30];
  byte counter;
  if (Serial.available()){
    delay(100); // Warte auf das Eintreffen aller Zeichen vom seriellen Monitor
    memset(linebuf,0,sizeof(linebuf)); // Zeilenpuffer löschen
    counter=0; // Zähler auf Null
    while (Serial.available()){
      linebuf[counter]=Serial.read(); // Zeichen in den Zeilenpuffer einfügen
      if (counter<sizeof(linebuf)-1) counter++; // Zeichenzähler erhöhen
    }
    // Wenn in der gelesenen Zeile das Wort 'set' vorkommt dann...
    //(Hier muss man bedenken das die Suche nach 'set' auch nach x Zeichen ein positives Ergebnis liefern wird, zbsp. 123set 09.01.2016 12:00:00)
    if (strstr(linebuf,"set")==linebuf){ 
      tag=getIntFromString (linebuf,1);
      monat=getIntFromString (linebuf,2);
      jahr=getIntFromString (linebuf,3);
      stunde=getIntFromString (linebuf,4);
      minute=getIntFromString (linebuf,5);
      sekunde=getIntFromString (linebuf,6);
    } else {
      Serial.println("Befehl unbekannt.");
      return;
    }
    // Ausgelesene Werte einer groben Plausibilitätsprüfung unterziehen:
    if (!checkDateTime(jahr, monat, tag, stunde, minute, sekunde)){
      Serial.println(linebuf);
      Serial.println("Fehlerhafte Zeitangabe im 'set' Befehl");
      Serial.println("Beispiel: set 28.08.2013 10:54");
      return;
    }
    rtcWriteTime(jahr, monat, tag, stunde, minute, sekunde);
    Serial.println("Zeit und Datum wurden auf neue Werte gesetzt.");
  }
}
 
//Prüft das eingegebene Datum auf korrektheit.
boolean checkDateTime(int jahr, int monat, int tag, int stunde, int minute, int sekunde){
   boolean result = false;
   if(jahr>2000){
     result = true;  
   } else {
     return false;
   }
   // Schaltjahr prüfen
   if(jahr % 400 == 0 || (jahr % 100 != 0 && jahr % 4 == 0)){
     //Wenn es ein Schaltjahr ist dann den Wert 29 in das Array an der Stelle 1 für den Monat Februar schreiben.
     daysInMonth[1]=29;
   }
   
   //Monat muss kleiner 13 sein.
   if (monat<13){
      if( tag <= daysInMonth[monat-1] ){
        result = true;
      }
   } else {
     return false;
   }
    
  //Wert für Stunde muss zwischen 0 und 24 liegen,
  //Wert für Minute und sekunde muss zwischen 0 und 59 liegen
  if(stunde <24 && minute <60 && sekunde <60 && stunde >= 0 && minute >=0 && sekunde >=0){
        result = true;
  } else {
     return false;
   }
   
   return result;
}

Video