Morsecodes mit Seeeduino Lotus und Grove Shields

In diesem Beitrag möchte ich dir zeigen wie du Text als Morsecodes mit dem Seeeduino Lotus und den Grove Shields LED & Piezo Buzzer ausgibst.

Die Eingabe des Textes erfolgt über den seriellen Monitor der Arduino IDE.

das Morsealphabet

Das Morsealphabet besteht aus Zahlen, Buchstaben und Sonderzeichen welche in eine normierte Strich / Punkt Notation umgewandelt werden. 

A	· –	B	– · · ·	C	– · – ·
D	– · ·	E	·	F	· · – ·
G	– – ·	H	· · · ·	I	· ·
J	· – – –	K	– · –	L	· – · ·
M	– –	N	– ·	O	– – –
P	· – – ·	Q	– – · –	R	· – ·
S	· · ·	T	–	U	· · –
V	· · · –	W	· – –	X	– · · –
Y	– · – –	Z	– – · ·
1	· – – – –	2	· · – – –	3	· · · – –
4	· · · · –	5	· · · · ·	6	– · · · ·
7	– – · · ·	8	– – – · ·	9	– – – – ·
0	– – – – –
.	· – · – · –	,	– – · · – –	:	– – – · · ·
;	– · – · – ·	?	· · – – · ·	!	– · – · – –
–	– · · · · –	_	· · – – · –	(	– · – – ·
)	– · – – · –	‚	· – – – – ·	„	· – · · – ·
=	– · · · –	+	· – · – ·	/	– · · – ·
@	· – – · – ·

benötigte Bauteile für diesen Beitrag

Für den nachbau dieses Beitrages empfehle ich dir das „Grove Beginner Kit for Arduino“ von Seeedstudio welches ich im bereits im separaten Beitrag Vorstellung – Seeedstudio – „Grove Beginner Kit for Arduino“ vorgestellt habe.

In diesem Kit sind alle benötigten Bauteile enthalten und du benötigst nur ein passendes Datenkabel. 

Du kannst dir natürlich auch die Bauteile einzeln über zbsp. ebay.de erwerben.

• Grove LED Shield,
• Grove Piezo Buzzer Shield,
• Grove 0,96″ OLED Display

Als Microcontroller verwende ich den Seeeduino Lotus du kannst natürlich auch einen einfachen Arduino UNO verwenden. Jedoch benötigst du dann einen zusätzlichen Adapter für die Grove Shields.

Programmieren

Da in dem Grove Kit die Bauteile bereits verdrahtet sind nutze ich die dort verwendeten Pins du kannst diese natürlich auch selber konfigurieren kannst.

Da wir die Zeichen über die serielle Schnittstelle empfangen wollen und diese Daten als Character vorliegen legen wir uns ein 2 Dimensionales Array mit den Werten aus der Morsecode Tabelle an.

#include "morsecodes.h"

//rote, 5mm LED am digitalen Pin D4 angeschlossen
#define ledPin 4
//Piezo Buzzer am digitalen Pin D5 angeschlossen
#define buzzerPin 5

void setup() {
  //beginn der seriellen Kommunikation mit 9600baud
  Serial.begin(9600);

  //definieren das die Pins der LED & der Piezo Buzzer als Ausgang dienen
  pinMode(ledPin, OUTPUT);
  pinMode(buzzerPin, OUTPUT);
}

void loop() {
  //Wenn Daten an der seriellen Schnittstelle anliegen dann...
  if (Serial.available() > 0) {
    //empfangen der Daten
    int data = Serial.read();   
    //Wenn ein Leerzeichen dann eine Pause von 2sek.
    if (data == 32) {
      delay(2000);
    } else if (data != 10) { //Wenn nicht das Zeichen für Zeilenumbruch, dann...
      //umwandeln von einem Zahlenwert in ein Character
      char c = char(data);
      //Ausgeben der Zeichen
      Serial.print(c);      
      Serial.print(": ");
      //Ausgeben der Morsezeichen
      blinkChar(c, ledPin, buzzerPin);
    } 
  }
}

Für den obrigen Code benötigst du zusätzlich noch die kleine Bibliothek „morsecode.h“.
In dieser sind die verschiedenen Morsecodes mit den Characters verknüpft.

Mit Hilfe der Funktion „findByChar“ kann ein MorseCode anhand eines Characters gefunden werden und mit der Funktion „blinkChar“ wird ein MorseCode ausgegeben.

class MorseCode {
  public:
    char _sign;
    String _code;
    MorseCode(char sign, String code) {
      _sign = sign;
      _code = code;
    }
 
};

const int CODE_COUNT = 78;
MorseCode _EMPTY = MorseCode(' ', "");

MorseCode codes[CODE_COUNT] = {
    MorseCode('A', ".-"), MorseCode('B', "-..."), MorseCode('C', "-.-."),
    MorseCode('D', "-.."), MorseCode('E', "."), MorseCode('F', "..-."),
    MorseCode('G', "--."), MorseCode('H', "...."), MorseCode('I', ".."),
    MorseCode('J', ".---"), MorseCode('K', "-.-"), MorseCode('L', ".-.."),
    MorseCode('M', "--"), MorseCode('N', "-."), MorseCode('O', "---"),
    MorseCode('P', ".--."), MorseCode('Q', "--.-"), MorseCode('R', ".-."),
    MorseCode('S', "..."), MorseCode('T', "-"), MorseCode('U', "..-"),
    MorseCode('V', "...-"), MorseCode('W', ".--"), MorseCode('X', "-..-"),
    MorseCode('Y', "-.--"), MorseCode('Z', "--.."),
    MorseCode('a', ".-"), MorseCode('b', "-..."), MorseCode('c', "-.-."),
    MorseCode('d', "-.."), MorseCode('e', "."), MorseCode('f', "..-."),
    MorseCode('g', "--."), MorseCode('h', "...."), MorseCode('i', ".."),
    MorseCode('j', ".---"), MorseCode('k', "-.-"), MorseCode('l', ".-.."),
    MorseCode('m', "--"), MorseCode('n', "-."), MorseCode('o', "---"),
    MorseCode('p', ".--."), MorseCode('q', "--.-"), MorseCode('r', ".-."),
    MorseCode('s', "..."), MorseCode('t', "-"), MorseCode('u', "..-"),
    MorseCode('v', "...-"), MorseCode('w', ".--"), MorseCode('x', "-..-"),
    MorseCode('y', "-.--"), MorseCode('z', "--.."),
    MorseCode('1', ".----"), MorseCode('2', "..---"), MorseCode('3', "...--"),
    MorseCode('4', "....-"), MorseCode('5', "....."), MorseCode('6', "-...."),
    MorseCode('7', "--..."), MorseCode('8', "---.."), MorseCode('9', "----."),
    MorseCode('0', "-----"),
    MorseCode('.', ".-.-.-"), MorseCode(',', "--..--"), MorseCode(':', "---..."),
    MorseCode(';', "-.-.-."), MorseCode('?', "..--.."), MorseCode('!', "-.-.--"),
    MorseCode('-', "-....-"), MorseCode('_', "..--.-"), MorseCode('(', "-.--."),
    MorseCode(')', "-.--.-"), MorseCode('\'', ".----."), MorseCode('"', ".-..-."),
    MorseCode('=', "-...-"), MorseCode('+', ".-.-."), MorseCode('/', "-..-."),
    MorseCode('@', ".--.-.")
};

MorseCode findByChar(char c){
  for(int i = 0;i<CODE_COUNT;i++){
      if(codes[i]._sign == c){
          return codes[i];
      }
  }
  return _EMPTY;
}

const int pause = 750;

const int frequenz = 500;
const int duration_long = 1500;
const int duration_short = 500;

void blinkChar(char c, int ledPin, int buzzerPin){
    MorseCode code = findByChar(c);	
    for (int i=0;i<code._code.length();i++){		
        int duration = duration_long;		
        char elem = code._code.charAt(i);
        Serial.print(elem);
        if(elem == '.'){			
            duration = duration_short;
        }
        digitalWrite(ledPin, HIGH);
        tone(buzzerPin, frequenz);
        delay(duration);
        digitalWrite(ledPin, LOW);		
        noTone(buzzerPin);
        delay(pause);
    }
    Serial.println("");
}