Funduino-Cube programmieren #2: DHT11 Sensor & OLED-Display

In diesem Beitrag möchte ich dir zeigen, wie du die Sensordaten vom DHT11 Sensor am OLED-Display auf dem Funduino-Cube programmierst.

Funduino-Cube programmieren #2: DHT11 Sensor & OLED Display
Funduino-Cube programmieren #2: DHT11 Sensor & OLED-Display

Wie du den DHT11 Sensor am Arduino programmierst und die Sensordaten auf einem Display anzeigst, habe ich dir bereits in Beiträgen auf meinem Blog gezeigt.

Im ersten Beitrag Funduino-Cube programmieren #1: LEDs habe ich dir bereits gezeigt, wie du die LEDs programmieren kannst. Hier soll es speziell um den Funduino-Cube gehen, welcher ein vordefiniertes Pinout hat.

Anschluss des Sensors & des OLED-Displays

Der Sensor und das Display sind wie nachfolgend aufgelistet am Arduino Nano V3 angeschlossen.

BauteilArduino Nano V3
DHT11
GNDGND
VCC5V
DATAdigitaler Pin D12
OLED-Display
GNDGND
VCC5V
SCLanaloger Pin A5
SDAanaloger Pin A4

Das OLED Display wird auf den Funduino-Cube in meinem Fall auf eine 4-polige Buchsenleiste gesteckt. Des Weiteren habe ich für die Einstellung der Spannungsversorgung Jumper gewählt, somit kann ich das Display einfach austauschen und muss nur den Jumper umstecken.

Anschluss des OLED Displays auf dem Funduino-Cube
Anschluss des OLED Displays auf dem Funduino-Cube

Programmieren des DHT11 Sensors & OLED Display

Für die Programmierung des Sensors & des OLED Displays benötigst du noch zusätzlich jeweils eine Bibliothek. Diese Bibliothek kannst du über den Bibliotheksverwalter der Arduino IDE 2.0 (und auch über die Classic-Variante 1.8) installieren.

Benötigte Bibliotheken

Den Bibliotheksverwalter findest du in der Arduino IDE 2.0 auf der linken Seite (1), in diesem suchen wir zunächst nach „DHT11“ (2) und wählen in dem Eintrag „DHTNEW by Rob Tillaart“ die Schaltfläche „INSTALL“ (3). Für das OLED-Display benötigen wir die Bibliothek für den verbauten Chip „SSD1306“ diesen suchen wir ebenfalls (4) und wählen hier die Adafruit SSD1306 by Adafruit Bibliothek.

Zum OLED-Display müssen wir zusätzlich noch zwei weitere Bibliotheken installieren. Diese benötigen wir, um das Display anzusteuern und somit wählen wir hier
die Schaltfläche „INSTALL ALL“.

Programmieren in der Arduino IDE 2.0

Nachdem wir die beiden Bibliotheken installiert haben, können wir mit der Programmierung beginnen.

//Bibliothek zum ansteuern / auslesen
//des DHT11 Sensors
#include <dhtnew.h>

//Bibliotheken zum ansteuern
//des OLED Displays
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

//Auslösung des OLED Displays
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 32

//Reset Pin
#define OLED_RESET -1
//I2C Adresse des Displays
#define SCREEN_ADDRESS 0x3C
//ein Objekt mit den zuvor definierten Werten initialisieren
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

//der DHT11 Sensor ist am digitalen Pin D12 angeschlossen
#define dht11SensorPin 12

//eine Instanz des Objektes DHTNEW initialisieren
DHTNEW dhtSensor(dht11SensorPin);

//die Pause zwischen dem anzeigen der Werte auf dem Display
const int PAUSE = 1000;

void setup() {
  //begin der seriellen Kommunikation mit 9600 baud
  Serial.begin(9600);

  //begin der Kommunikation mit dem OLED Display
  display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS);
  display.display();
}

//Eine Funktion welche uns auf dem Display die Messwerte anzeigt.
void displayMessurement(String text, String sign, float value, int decimalplaces) {
  //Display leeren
  display.clearDisplay();
  //Schriftgröße auf 1 setzen
  display.setTextSize(1);
  //Schriftfarbe auf weiß setzen
  display.setTextColor(SSD1306_WHITE);
  //setzen des Cursors auf die Spalte 10 und die Zeile 0
  display.setCursor(10, 0);
  //schreiben des Textes an die Position vom Cursor
  display.println(text);
  //Schriftgröße auf 2 setzen
  display.setTextSize(2);
  //setzen des Cursors auf die Spalte 30 und die Zeile 15
  display.setCursor(30, 15);
  //schreiben des Textes an die Position vom Cursor
  display.println(String(value, decimalplaces) + sign);
  //schreiben des Puffers aus dem Speicher auf das Display
  display.display();
}

void loop() {
  //lesen der Sensorwerte
  dhtSensor.read();
  //lesen des Sensorwertes für die rel. Luftfeuchtigkeit
  float humidity = dhtSensor.getHumidity();
  //lesen des Sensorwertes für die Temperatur
  float temperature = dhtSensor.getTemperature();

  //Ausgeben der Werte auf der seriellen Schnittstelle
  Serial.print("rel. Luftfeuchtigkeit: ");
  Serial.print(String(humidity, 2));
  Serial.println(" %");

  Serial.print("Temperatur: ");
  Serial.print(String(temperature, 2));
  Serial.println(" °C");
  Serial.println("------------------------------");

  //Schreiben der Sensorwerte auf dem Display
  displayMessurement("Luftfeuchtigkeit", " %", humidity, 2);
  //Pause zwischen den beiden Werten
  delay(PAUSE);
  displayMessurement("Temperatur", " C", temperature, 2);
  //Pause
  delay(PAUSE);
}

Die Programmierung und das Schreiben der Messwerte auf das OLED-Display war nicht besonders spannend oder eine Herausforderung, denn zu beiden Bibliotheken liegen jeweils Beispiele bei, aus welchen man sich einfach Codefragmente entnehmen kann.

Kommentar hinterlassen

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert