Arduino UNO R3 Projekt – Ultraschallabstandssensor HC-SR04 & Piezo Buzzer

In diesem Beitrag möchte ich dir zeigen wie du mit einem Impuls eines Ultraschallabstandssensor vom Typ HC-SR04 einen Piezo Buzzer am Arduino UNO R3 programmierst.

Die Idee zu diesem Beitrag kam von einem Leser meines Blogs und daher geht zunächst ein Dank an Antonio T..

Benötigte Ressourcen für dieses Projekt

Für den Nachbau dieses kleines Projektes, benötigst du:

• Arduino UNO R3,
  • USB Datenkabel Typ B,
• Piezo Buzzer*,
• Ultraschallabstandssensor HC-SR04,
• ein Breadboard mit min. 400 Pin,
• diverse Breadboardkabel

* Den Piezo Buzzer bekommst du in mehreren Varianten, für den Arduino UNO R3 benötigst du eine 5V Version. Die 3V Version kannst du für zbsp. den ESP8266 verwenden. Der Grund ist hier recht einfach die Mikrocontroller haben eine unterschiedliche Spannung an den GPIO Pins und daher liegt bei einem HIGH Signal entweder 3.3V oder 5V an.

Aufbau der Schaltung

Hier nun die Tabelle mit den Zuordnungen der Pins der Bauteile zum Arduino UNO R3.

Bauteil	Arduino UNO R3
Piezo Buzzer
+	digitaler Pin D8
–	GND
Ultraschallabstandssensor HC-SR04
VCC	5V
Trigger	digitaler Pin D7
Echo	digitaler Pin D6
GND	GND

Du kannst diese Belegung auch nutzen um den Aufbau an einem Arduino Nano V3 oder einen anderen baugleichen Mikrocontroller zu verwenden.

In meinem Fall verwende ich einen Keyestudio UNO R3, welcher ebenso gut funktioniert wie ein Arduino UNO R3, jedoch bietet der Mikrocontroller von Keyestudio ein paar nette Feature mehr.

Programmieren in der Arduino IDE

Wie du den Ultraschallabstandssensor HC-SR04 am Arduino UNO programmierst, habe ich dir bereits in einigen Beiträgen auf meinem Blog gezeigt. Und auch dem Piezo Buzzer habe ich schon ein paar Beiträge gewidmet.

Daher möchte ich dir hier lediglich zeigen wie du auf eine Zustandsänderung vor dem Ultraschallabstandssensor reagieren und den Piezo Buzzer ertönen lassen kannst.

//Konstanten / Variablen für den Ultraschall Abstandssensor HC-SR04
const int TrigPin = 7;  //Der PIN welcher auf das Trigger Signal gelegt wird.
const int EchoPin = 6;  //Der PIN welcher auf das Echo Signal gelegt wird.
float distance = 0;
float offset = 4;

const int BuzzerPin = 8;

const int maxBeep = 5;

void setup() {
  Serial.begin(9600); //Die Übertragungsgeschwindigkeit setzen.
  pinMode(TrigPin, OUTPUT); //Den Trigger auf das Output Signal des Arduino UNO R3 setzen.
  pinMode(EchoPin, INPUT);  //Das Echo auf das Input Signal des Arduino UNO R3 setzen.

  pinMode(BuzzerPin, OUTPUT); //Den positiven Pin des Piezo Buzzers als Ausgang definieren.
}

void loop() {
  // lesen des aktuellen Wertes des Ultraschallabstandssensors
  float newDistance = getUltrasonicValue();
  // Ausgeben des Wertes auf der seriellen Schnittstelle
  Serial.println(newDistance);
  // Wenn der neue Wert größer oder kleiner als der alte Wert (inkl. dem Offset) ist,
  // dann soll ein Ton ausgegeben werden.
  if (newDistance > (distance + offset) || newDistance < (distance - offset)){
    // Ausgeben von Tönen
    for(int i=0;i<maxBeep;i++){
      // einen Ton in der Frequenz von 500 Hz ausgeben
      tone(BuzzerPin, 500);    
      // eine Pause von 50ms.
      delay(50);
      // die Ausgabe von Tönen stoppen
      noTone(BuzzerPin);
      // eine Pause von 250ms.
      delay(250);
      // Ausgeben des Textes auf der seriellen Schnittstelle.
      Serial.println("beep");
    }    
    // die Ausgabe von Tönen stoppen
    noTone(BuzzerPin);
    // zuweisen des neuen Wertes auf die globale Variable "distance"
    distance = newDistance;
  }
  delay(2500); //1sek. warten
}

float getUltrasonicValue() {
  digitalWrite(TrigPin, LOW); //Trigger Signal ausschalten
  delayMicroseconds(2);   //2 ms warten
  digitalWrite(TrigPin, HIGH);  //Trigger Signal einschalten
  delayMicroseconds(10);  //10ms warten
  digitalWrite(TrigPin, LOW); //Trigger Signal ausschalten
  float cm = pulseIn(EchoPin, HIGH) / 58.0; //Das Empfangene Echo Signal in cm umrechnen
  //Da der Sensor mit einer Messgenauigkeit von 0,3cm arbeitet können wir das
  //Ergbnis auf 2 Nachkommastellen begrenzen
  return (int(cm * 100.0)) / 100.0;
}

Video – Ultraschallabstandssensor zum aktivieren eines Piezo Buzzer am Arduino