Arduino Plug and Make Kit: Richtungsanzeige mit Modulino Movement

Das neue Arduino Plug and Make Kit habe ich dir bereits im passenden Beitrag vorgestellt, heute soll es um den Modulino Movement gehen, mit welchen man auf dem Arduino UNO R4 WiFi die Richtung anzeigen lassen kann.

Arduino Plug and Make Kit: Richtungsanzeige mit Modulino Movement

Dieses Video auf YouTube ansehen.

Der Modulino Movement Sensor ist ein 6 Achsen Lagesensor vom Typ LSM6DSOXTR dieser verfügt über zwei Qwiic Schnittstellen, mit welche dieser direkt mit dem Mikrocontroller verbunden wird. Mit der zweiten Schnittstelle kannst du zusätzlich noch andere Sensoren / Aktoren anschließen. Die Sensoren / Aktoren werden via I2C angesprochen und verfügen somit jeweils über eine eindeutige Adresse.

Disclaimer: Ich habe das Arduino Plug and Make Kit für knapp 90 € (inklusive Versandkosten) selbst über den offiziellen Shop gekauft. Alle hier geäußerten Meinungen sind meine eigenen und wurden nicht von Arduino gesponsert oder beeinflusst.

Inhaltsverzeichnis

• Überblick über das Arduino Plug and Make Kit
• Aufbau der Schaltung – Arduino UNO R4 WiFi mit Modulino Movement Sensor
• Programmieren des Modulino Movement in der Arduino IDE
  • Anzeigen der Richtung mit der LED Matrix vom Arduino UNO R4 WiFi

Überblick über das Arduino Plug and Make Kit

Zum Lieferumfang des Arduino Plug and Make Kit gehört unteranderem die Sensoren / Aktoren:

• Modulino Knob – ein Rotary Encoder mit Push Funktion,
• Modulino Pixels – ein 8fach RGB LED Modul,
• Modulino Distance – ein ToF Modul zum Messen von Entfernungen,
• Modulino Movement – ein 6 Achsen Lagesensor,
• Modulino Buzzer – ein Piezo Buzzer zum Erzeugen von Tönen,
• Modulino Thermo – ein Sensor zum Messen von Temperatur & rel. Luftfeuchtigkeit,
• Modulino Buttons – ein Modul mit 3 Taster

Und natürlich gehört noch der Arduino UNO R4 WiFi dazu, welcher über die benötigte Qwiic Schnittstelle verfügt.

Aufbau der Schaltung – Arduino UNO R4 WiFi mit Modulino Movement Sensor

Die Schaltung ist recht schnell auf der Modulino Base aufgebaut, mithilfe der mitgelieferten Schrauben und Abstandshalter wird der Mikrocontroller an seinen Platz geschraubt und im unteren Bereich die Sensoren / Aktoren.

Hier zeigt sich leider, dass die Kabel doch etwas kurz geraten sind. Wenn der Movement Sensor angeschraubt wird, sodass dieser parallel zum Mikrocontroller liegt, ist das Qwiic Kabel doch recht stramm.

Programmieren des Modulino Movement in der Arduino IDE

Auf der Seite https://courses.arduino.cc/plugandmake/lessons/modulino-movement/ findest du eine englische Dokumentation zum Modulino Movement mit einem Beispiel, welches ich dir nachfolgend einmal abgewandelt zeige.

//Bibliothek für die Modulino Sensoren / Aktoren
#include "Modulino.h"

//erzeugen einer Objektinstanz vom Typ
//Modulino Movement
ModulinoMovement movement;

void setup() {
  //beginn der seriellen Kommunikation mit 9600 baud
  Serial.begin(9600);
  //begin / Initialisierung der Kommunikation
  Modulino.begin();
  //einrichten der I2C Verbindung zum Sensor
  movement.begin();
}

void loop() {
  //aktualisieren der Daten vom Sensor
  movement.update();
  //Ausgeben der Daten auf der seriellen Schnittstelle
  Serial.print("Lage: [");
  Serial.print(movement.getX(), 3);
  Serial.print(",");
  Serial.print(movement.getY(), 3);
  Serial.print(",");
  Serial.print(movement.getZ(), 3);
  Serial.println("]");
}

Anzeigen der Richtung mit der LED Matrix vom Arduino UNO R4 WiFi

#include "Modulino.h"
#include "Arduino_LED_Matrix.h"
#include "frames.h"

ModulinoMovement movement;

ArduinoLEDMatrix matrix;

float x, y, z;
float difference = 0.3;

const int ROWS = 8;
const int COLS = 12;

const int PAUSE = 200;

void setup() {
  Serial.begin(9600);
  Modulino.begin();
  movement.begin();
  matrix.begin();
}

void loop() {
  movement.update();

  x = movement.getX();
  y = movement.getY();
  z = movement.getZ();

  if (abs(x) >= 0 && abs(x) <= difference && abs(y) >= 0 && abs(y) <= difference) {
    matrix.renderBitmap(circle, ROWS, COLS);
  } else if (abs(x) >= abs(y)) {
    if (x > 0) {
      matrix.renderBitmap(pfeilRechts, ROWS, COLS);
    } else {
      matrix.renderBitmap(pfeilLinks, ROWS, COLS);
    }
  } else if (abs(y) >= abs(x)) {
    if (y > 0) {
      matrix.renderBitmap(pfeilVorne, ROWS, COLS);
    } else {
      matrix.renderBitmap(pfeilHinten, ROWS, COLS);      
    }
  }

  delay(PAUSE);
}