Arduino Lektion 48: Temperatursensor DS18B20

In diesem Beitrag stelle ich dir den Temperatursensor DS18B20 vor und zeige dir wie dieser am Arduino angeschlossen und programmiert wird.

Den Temperatursensor DS18B20 gibt es in 2 verschiedenen Varianten auf dem Markt. Einmal als Wasser geschützter Sensor und einmal als “normales” Bauteil.

Der Sensor hat sehr viel Ähnlichkeit mit dem LM35DZ daher sollte man aufpassen wenn man verschiedene Sensoren auf dem Schreibtisch herumliegen hat. 🙂

Technische Daten des DS18B20

• Betriebsspannung – 3.0V bis 5.5V
• Messbarer Temperaturbereich von -55 °C bis +125 °C
• Toleranz – ±0.5 °C
• Auflösung des Thermometers von 9 bis 12bit
• jeder Sensor hat einen eindeutigen und einmaligen 64bit Code auf dem onboard ROM

Anschluss

Der Sensor DS18B20 verfügt über 3 Beinchen welche wie folgt bezeichnet werden.

Die flache Seite ist hier der Indikator für die Ableserichtung!

DS18B20	Arduino UNO
GND	GND
DATA	digitaler PIN 2
Vdd	5V

Schaltung

Möchte man den Sensor an den Arduino anschließen so benötigt man zusätzlich einen 4.7 kOhm Widerstand.

Möchtest du also diese Schaltung nachbauen, so benötigst du:

• 1x Breadboard, 400 Pin
• 3x Breadboardkabel, männlich – männlich
• 1x Arduino Nano
• 1x 4,7kOhm Widerstand
• 1x Sensor DS18B20

Schaltplan

Quellcode

Für den nachfolgenden Quellcode werden 2 zusätzliche Bibliotheken benötigt.
Einmal die OneWire sowie die Arduino-Temperature-Control-Library, welche vom GitHub Repository von MilesBurton geladen werden kann.

//Einbinden der Bibliotheken
#include <OneWire.h>
#include <DallasTemperature.h>

#define ONE_WIRE_BUS 2  //Sensor DS18B20 am digitalen Pin 2

OneWire oneWire(ONE_WIRE_BUS); //

//Übergabe der OnewWire Referenz zum kommunizieren mit dem Sensor.
DallasTemperature sensors(&oneWire);

int sensorCount;

void setup(void) { 
 Serial.begin(9600); //Starten der seriellen Kommunikation mit 9600 baud
 Serial.println("Temperatursensor - DS18B20"); 
 sensors.begin(); //Starten der Kommunikation mit dem Sensor
 sensorCount = sensors.getDS18Count(); //Lesen der Anzahl der angeschlossenen Temperatursensoren.
} 

void loop(void){ 
 if(sensorCount ==0){
   Serial.println("Es wurde kein Temperatursensor gefunden!");
   Serial.println("Bitte überprüfe deine Schaltung!");
 }
 //Es können mehr als 1 Temperatursensor am Datenbus angschlossen werden.
 //Anfordern der Temperaturwerte aller angeschlossenen Temperatursensoren.
 sensors.requestTemperatures(); 

 //Ausgabe aller Werte der angeschlossenen Temperatursensoren.
 for(int i=0;i<sensorCount;i++){
  Serial.print(i); 
  Serial.println(". Temperatur :"); 
  printValue(sensors.getTempCByIndex(i), "°C");
  printValue(sensors.getTempFByIndex(i), "°F");
 }
 
 delay(1000); //Pause von 1 Sekunde.
} 

void printValue(float value, String text){
  Serial.print("\t\t");
  Serial.print(value);
  Serial.println(text);
}

Ausgabe auf dem seriellen Monitor

Das oben gezeigte Sketch erzeugt folgende Ausgabe auf dem seriellen Monitor der Arduino IDE.
Wenn mehr als 1 Temperatursensor enthalten ist, so werden diese von 0…n aufgelistet.

Video

In diesem Video möchte ich nun erläutern wie diese Schaltung aufgebaut wird.