Arduino Lektion 51: NTC-Temperatursensor mit LM393-Komparator

In dieser Lektion schauen wir uns ein weit verbreitetes Modul an, das oft als „LM393 Temperatursensor“ bezeichnet wird. Der Name ist etwas irreführend, denn der LM393 ist kein Temperatursensor, sondern ein Komparator-Chip.
Das eigentliche Temperaturelement ist ein NTC-Widerstand (Thermistor), dessen Widerstand sich temperaturabhängig verändert.

Der LM393 sorgt dafür, dass aus diesem analogen Signal ein digitales Schaltsignal wird – z. B. wenn eine bestimmte Temperatur überschritten wird. So kannst du den Sensor flexibel einsetzen, um Temperaturgrenzen zu überwachen oder automatische Steuerungen zu realisieren.

Technische Daten des LM393

• Betriebsspannung – 3.3V bis 5V
• Ausgangsstrom – 15mA
• Abmaße – 35 mm x 15 mm
• Temperaturmessbereich  – +20 °C bis +80 °C

Aufbau

Das Modul besteht aus drei Hauptkomponenten:

1. NTC-Thermistor – misst die Temperatur über seinen Widerstand
2. LM393-Komparator – vergleicht die Sensorspannung mit einem Referenzwert
3. Potentiometer – stellt den Schwellwert für den Digitalausgang ein

Zusätzlich besitzt das Modul zwei Status-LEDs:

• Eine Power-LED, die anzeigt, dass das Modul mit Spannung versorgt wird
• Eine Signal-LED, die beim Erreichen des Schwellwerts aktiviert wird

Anschluss

Der Sensor verfügt über 4 Pins welche wie folgt mit dem Arduino UNO verbunden werden.

Pin	Arduino UNO
A0	analoger Pin A0
+	5V
G	GND
D0	digitaler Pin 7

Schaltung

Einstellen des Schwellwertes

Der Schwellwert des Temperatursensors wird über einen Drehpotentiometer eingestellt.

Dreht man diesen im Uhrzeigersinn so wird der Schwellwert erhöht und dreht man diesen gegen den Uhrzeigersinn so wird dieser Wert verkleinert.

Da dieser Sensor „nur“ einen Momentanen Temperaturwert ausgeben kann, muss hier etwas experimentiert werden wenn man einen ganz bestimmten Schwellwert haben möchte. Hier schwächelt der Sensor leider etwas.

Wenn der Schwellwert erreicht ist, dann wird der digitale Ausgang des Sensors auf HIGH gesetzt sowie wird eine onboard LED eingeschaltet und es kann ein weiterer Aktor geschaltet werden.

Quellcode

const int digitalPin = 7; //D0 vom LM393
const int analogPin = A0; //A0 vom LM393
const int ledPin = 13;  // internet LED an Pin 13

//Der MakerUNO verfügt über einen verbauten Piezobuzzer
//dieser wird über den Pin 8 angesprochen.
const int buzzerPin = 8; 

void setup(){
   Serial.begin(9600); //Beginn der seriellen Kommunikation mit 9600 baud
   pinMode(ledPin, OUTPUT); 
   pinMode(buzzerPin, OUTPUT);
   pinMode(digitalPin, INPUT);
}

void loop(){
   //lesen des analogen Wertes
   int analogValue = analogRead(analogPin);
   //lesen des zustandes, Schwellwert erreicht / nicht erreicht
   boolean state = digitalRead(digitalPin);
   
   //Ausgabe ob der Schwellwert erreicht wurde.
   Serial.print("digitaler Ausgang ist ");
   Serial.println(state==HIGH?"AN": "AUS"); 
   
   //Ausgabe der Temperatur.
   Serial.print("Temperatur:");
   Serial.println(getTempC(analogValue));

   //Wenn der Schwellwert des Temperatursensors erreicht
   //wurde, dann soll die interne LED am PIN 13 aufleuchten.
   digitalWrite(ledPin,state);     

   //Wenn der Schwellwert erreicht wurde so soll ein Ton erzeugt werden.
   //Hier könnte man auch ein Relais anschließen oder sonstige andere Aktoren
   //welche auf den Umstand hinweisen sollen.
   if(state==HIGH){
      tone(buzzerPin, 1000, 500);
   }
   
   delay(1000); //kleine Pause von 1 Sekunde.
}

double getTempC(int analogValue){
  int mappedAnalogValue = map(analogValue, 0, 1023, 1023, 0);
  double tempC = log(((10240000 / mappedAnalogValue) - 10000));
  tempC = 1 / (0.001129148 + (0.000234125 * tempC) + (0.0000000876741 * tempC * tempC * tempC));
  tempC = tempC - 273.15;
  return tempC;
}

Video

Fazit

Das sogenannte LM393-Temperatursensor-Modul ist eigentlich ein NTC-Sensor mit Komparator, der dir sowohl analoge Messwerte als auch ein digitales Schaltsignal liefert.
Mit nur wenigen Anschlüssen und etwas Code lässt sich so eine einfache Temperaturüberwachung umsetzen – ideal für Lüftersteuerungen, Heizungen oder andere Automatisierungen.
Zudem vermittelt das Modul ein gutes Verständnis, wie ein Komparator-IC arbeitet und analoge Signale in digitale Schaltsignale umwandelt.

Letzte Aktualisierung am: 06. Oktober 2025